Private Declare Function PathFileExists Lib "shlwapi.dll" Alias _
  "PathFileExistsA" (ByVal pszPath As String) As Long
 
Public Function CSVFileToStringArray(strFilePath As String, _
                                     strErrorMsg As String, _
                                     strArray() As String) As Boolean
 
    Dim strTemp As String
    Dim lngCnt  As Long
    Dim intFF   As Integer
 
    If PathFileExists(strFilePath) <> 1 Then
        strErrorMsg = "Die angegeben Sprachdatei konnte nicht gefunden werden."
        CSVFileToStringArray = False
        Exit Function
    End If
 
    If FileLen(strFilePath) = 0 Then
        strErrorMsg = "Die angegeben Sprachdatei enthält keine Daten."
        CSVFileToStringArray = False
        Exit Function
    End If
 
    lngCnt = -1
    intFF = FreeFile
    Erase strArray()
    Open strFilePath For Input As #intFF
        Do Until EOF(intFF)
            Line Input #intFF, strTemp
            lngCnt = lngCnt + 1
            ReDim Preserve strArray(0 To lngCnt)
            strArray(lngCnt) = strTemp
        Loop
    Close #intFF
 
    CSVFileToStringArray = True
End Function
 
Public Function GetStringPartCSV(ByVal strCSV As String, _
                                 ByVal PartPosition As Long, _
                                 Optional ByVal strDelimiter As String = ";") _
                                 As String
    Dim strTemp     As String
    Dim strSplit()  As String
    strSplit = Split(strCSV, strDelimiter, , 1)
    strTemp = strSplit(PartPosition)
    Erase strSplit()
 
    GetStringPartCSV = strTemp
End Function
 
Private Sub Form_Load()
 
    Dim strErrMsg As String
    Dim strFilePath As String
    Dim strArrayCSV() As String
 
    strFilePath = "C:\test.csv"
 
    If CSVFileToStringArray(strFilePath, strErrMsg, strArrayCSV()) Then
        MsgBox "Sprachdatei erfolgreich geladen."
    Else
        MsgBox strErrMsg
        Unload Me
    End If
 
    Dim i As Long
    For i = 0 To UBound(strArrayCSV())
        List1.AddItem GetStringPartCSV(strArrayCSV(i), 0)
    Next i
 
End Sub

Ohne Mampf, kein Kampf !