Public Function CSVFileToStringArray(strFilePath As String, _
                                     strErrorMsg As String, _
                                     strArray() As String, _
                                     lngStartLine As Long) As Boolean
 
    Dim strTemp As String
    Dim lngCnt  As Long
    Dim intFF   As Integer
 
    If PathFileExists(strFilePath) <> 1 Then
        strErrorMsg = "Die angegeben Sprachdatei konnte nicht gefunden werden."
        CSVFileToStringArray = False
        Exit Function
    End If
 
    If FileLen(strFilePath) = 0 Then
        strErrorMsg = "Die angegeben Sprachdatei enthält keine Daten."
        CSVFileToStringArray = False
        Exit Function
    End If
 
    lngCnt = -1
    intFF = FreeFile
    Erase strArray()
    Open strFilePath For Input As #intFF
        ' Bis zur Startlinie vortreten
        If lngStartLine > 1 Then
            For i = 1 To lngStartLine - 1
                Line Input #intFF, strTemp
            Next i
        End If
        ' CSV - einlesen
        Do Until EOF(intFF)
            Line Input #intFF, strTemp
            lngCnt = lngCnt + 1
            ReDim Preserve strArray(0 To lngCnt)
            strArray(lngCnt) = strTemp
        Loop
    Close #intFF
 
    CSVFileToStringArray = True
End Function
 
Public Function GetStringPart(ByVal strCSV As String, _
                              ByVal PartPosition As Long, _
                              Optional ByVal strDelimiter As String = ";") As _
                              String
 
    If InStr(1, strCSV, strDelimiter, 1) = 0 Then
        GetStringPart = vbNullString
        Exit Function
    End If
 
    Dim strTemp     As String
    Dim strSplit()  As String
    strSplit = Split(strCSV, strDelimiter, , 1)
    strTemp = strSplit(PartPosition)
    Erase strSplit()
 
    GetStringPart = strTemp
End Function
 
Private Sub Form_Load()
 
    Dim strErrMsg As String
    Dim strFilePath As String
    Dim strArrayCSV() As String
 
    strFilePath = "C:\test.csv"
 
    If CSVFileToStringArray(strFilePath, strErrMsg, strArrayCSV(), 7) Then
        MsgBox "Sprachdatei erfolgreich geladen."
    Else
        MsgBox strErrMsg
        Unload Me
    End If
 
    Dim i As Long
    Dim strTempPart As String
    For i = 0 To UBound(strArrayCSV())
        strTempPart = GetStringPart(strArrayCSV(i), 0)
        If Len(strTempPart) Then
            List1.AddItem strTempPart
        End If
    Next i
 
End Sub

Ohne Mampf, kein Kampf !