' Controls: 1 * Timer
Option Explicit
 
Private XShot!(), YShot!(), Speed!(), ActivShot() As Boolean
 
Private Sub Form_Load()
 
Dim i%
 
Randomize
With Me
  .ScaleMode = vbPixels
  .BackColor = RGB(0, 0, 64)
  .AutoRedraw = True
  .KeyPreview = True
  .Caption = Space$(20) & "Bitte eine Taste drücken"
End With
ReDim XShot(0), YShot(0), Speed(0), ActivShot(0)
Timer1.Interval = 30
Timer1.Enabled = True
For i = 1 To 20
  Call Form_KeyDown(0, 0)
Next i
 
End Sub
 
Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
 
Dim i%, flgFound As Boolean
 
flgFound = False
For i = 0 To UBound(ActivShot)
  If ActivShot(i) = False Then
    flgFound = True
    Exit For
  End If
Next i
If flgFound = False Then ReDim Preserve ActivShot(i), XShot(i), YShot(i), Speed( _
  i)
XShot(i) = 20 + Rnd * (Me.ScaleWidth - 40)
YShot(i) = Me.ScaleHeight
Speed(i) = 8 + Rnd * 8
ActivShot(i) = True
 
End Sub
 
Private Sub Timer1_Timer()
 
Dim i%, XP!, YP!
 
Me.Cls
For i = 0 To UBound(ActivShot)
  If ActivShot(i) = True Then
    XP = XShot(i)
    YP = YShot(i)
    Me.Line (XP - 1, YP)-Step(0, -10), vbYellow
    Me.Line (XP + 1, YP)-Step(0, -10), vbYellow
    Me.Line (XP, YP)-Step(0, -20), vbRed
    YShot(i) = YShot(i) - Speed(i)
    If YShot(i) < 0 Then ActivShot(i) = False
  End If
Next i
 
End Sub

Gruss,

Zardoz