'http://www.activevb.de/rubriken/faq/faq0155.html
Option Explicit
 
Private Declare Function MultiByteToWideChar Lib "kernel32.dll" (ByVal CodePage _
    As Long, ByVal dwFlags As Long, ByVal lpMultiByteStr As Long, ByVal _
    cbMultiByte _
    As Long, ByVal lpWideCharStr As Long, ByVal cchWideChar As Long) As Long
 
Private Const CP_UTF8 As Long = 65001
 
Private Function ConvertFromUTF8(ByRef Source() As Byte) As String
 
    Dim Size As Long
    Dim Pointer As Long
    Dim Length As Long
    Dim Buffer As String
 
    Size = UBound(Source) - LBound(Source) + 1
    Pointer = VarPtr(Source(LBound(Source)))
    Length = MultiByteToWideChar(CP_UTF8, 0, Pointer, Size, 0, 0)
    Buffer = Space$(Length)
    MultiByteToWideChar CP_UTF8, 0, Pointer, Size, StrPtr(Buffer), Length
    ConvertFromUTF8 = Buffer
 
End Function
 
Private Function ReadUTF8File(ByRef FileName As String) As String
 
    Dim FileNumber As Integer
    Dim Buffer() As Byte
 
    FileNumber = FreeFile
    Open FileName For Binary Access Read As #FileNumber
    ReDim Buffer(0 To LOF(FileNumber) - 1)
    Get #FileNumber, , Buffer
    Close #FileNumber
    ReadUTF8File = ConvertFromUTF8(Buffer)
 
End Function
'End activevb source
 
Private Sub Drive1_Change()
    Dir1.Path = Left$(Drive1.Drive, 1) & ":\"
End Sub
 
Private Sub Dir1_Change()
    File1.Path = Dir1.Path
End Sub
 
Private Sub File1_DblClick()
    Dim FileName As String
 
    Label1.Caption = vbNullString
 
    FileName = File1.Path
    If Right$(FileName, 1) <> "\" Then FileName = FileName & "\"
    FileName = FileName & File1.FileName
 
    Label1.Caption = ReadUTF8File(FileName)
 
End Sub