' zunächst die benötigten API-Deklarationen
Private Declare Function GetWindow Lib "user32" _
  (ByVal hWnd As Long, ByVal wCmd As Long) As Long
 
Private Declare Function GetClassName Lib "user32" _
  Alias "GetClassNameA" (ByVal hWnd As Long, _
  ByVal lpClassName As String, ByVal nMaxCount As Long) _
  As Long
 
Private Declare Function SendMessage Lib "user32" Alias _
  "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, _
  ByVal wParam As Long, lParam As Any) As Long
 
Private Declare Function GetWindowText Lib "user32" _
  Alias "GetWindowTextA" ( _
  ByVal hWnd As Long, _
  ByVal lpString As String, _
  ByVal cch As Long) As Long
 
 
Const WM_SYSCOMMAND = &H112
Const SC_CLOSE = &HF060
Const LNULL = 0&
 
Const GW_HWNDFIRST = 0
Const GW_HWNDNEXT = 2

Private Sub Form_Load()
  ' alle offenen IE-Fenster ermitteln
  Dim lRetVal As Long
  Dim sClassName As String
  Dim CurHWnd As Long
  Dim sBuffer As String
 
  List1.Clear
  CurHWnd = GetWindow(hWnd, GW_HWNDFIRST)
  Do While CurHWnd <> 0
    ' Klassennamen ermitteln
    sClassName = String$(256, " ")
    lRetVal = GetClassName(CurHWnd, sClassName, 255)
    sClassName = Left$(sClassName, InStr(sClassName, _
      Chr$(0)) - 1)
 
    If sClassName = "IEFrame" Then
      ' Fenster-Titel ermitteln
      sBuffer = Space$(256)
      lRetVal = GetWindowText(CurHWnd, sBuffer, Len(sBuffer))
      sBuffer = Left$(sBuffer, lRetVal)
 
      ' In ListBox einfügen
      List1.AddItem sBuffer
      List1.ItemData(List1.NewIndex) = CurHWnd
    End If
 
    ' Handle des nächsten Fensters
    ' 0, wenn kein weiteres Fenster vorhanden
    CurHWnd = GetWindow(CurHWnd, GW_HWNDNEXT)
  Loop
End Sub

Private Sub List1_DblClick()
  ' IE-Fenster schließen
  Dim nHWnd As Long
  nHWnd = List1.ItemData(List1.ListIndex)
 
  Call SendMessage(nHWnd, WM_SYSCOMMAND, SC_CLOSE, LNULL)
  List1.RemoveItem List1.ListIndex
End Sub

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de