'Beschreibung
'Bekanntlich wird beim Doppelklicken auf eine Datei entweder diese
'direkt ausgeführt (falls es sich um eine EXE- oder eben ausführbare
'Datei handelt) oder es wird die zu dieser Datei im System
'gespeicherte verknüpfte Anwendung geöffnet und die Datei dann als
'Parameter an die Anwendung übergeben (z.B. wird eine .doc-Datei
'autom. mit WordPad oder MS-Word geöffnet). Ist dem System der
'Dateityp nicht bekannt, so zeigt Windows von Haus aus den
'Verknüpfungs-Dialog (Öffnen mit...) an. Genau dieses Verhalten
'können auch Sie in Ihre eigenenen Anwendungen integrieren.
'
'Beispielaufruf
'DocumentOpen App.Path & "\test.dat"
'
'*************************************************************
 
 
 
Public Declare Function ShellExecute Lib "shell32.dll" _
    Alias "ShellExecuteA" (ByVal hWnd As Long, _
    ByVal lOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As Long
 
Public Declare Function GetSystemDirectory Lib "kernel32" _
  Alias "GetSystemDirectoryA" (ByVal lpBuffer As String, _
  ByVal nSize As Long) As Long
 
Public Declare Function GetDesktopWindow Lib "user32" () _
  As Long
 
Public Const SE_ERR_NOASSOC = 31
Public Const SE_ERR_NOTFOUND = 2
 
'Dokument öffnen und ggf. autom. den
'"Öffnen mit..." - Dialog anzeigen
Public Sub DocumentOpen(sFilename As String)
  Dim sDirectory As String
  Dim lRet As Long
  Dim DeskWin As Long
 
    DeskWin = GetDesktopWindow()
       lRet = ShellExecute(DeskWin, "open", sFilename, _
    vbNullString, vbNullString, vbNormalFocus)
 
     If lRet = SE_ERR_NOTFOUND Then
    'Datei nicht gefunden
    ElseIf lRet = SE_ERR_NOASSOC Then
    'Wenn die Dateierweiterung noch nicht bekannt ist...
    'wird der "Öffnen mit..."-Dialog angezeigt.
    sDirectory = Space(260)
    lRet = GetSystemDirectory(sDirectory, Len(sDirectory))
    sDirectory = Left(sDirectory, lRet)
    Call ShellExecute(DeskWin, vbNullString, _
      "RUNDLL32.EXE", "shell32.dll,OpenAs_RunDLL " & _
      sFilename, sDirectory, vbNormalFocus)
      End If
 
End Sub