Option Explicit
 
Private Declare Function CreateDCAsNull Lib "gdi32" Alias "CreateDCA" (ByVal _
  lpDriverName As String, lpDeviceName As Any, lpOutput As Any, lpInitData As _
  Any) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
 
Private Type RECT
  Left    As Long
  Top     As Long
  Right   As Long
  Bottom  As Long
End Type
Private Declare Function DrawText Lib "user32" Alias "DrawTextA" (ByVal hdc As _
  Long, ByVal lpStr As String, ByVal nCount As Long, lpRect As RECT, ByVal _
  wFormat As Long) As Long
Private Declare Function GetTextColor Lib "gdi32" (ByVal hdc As Long) As Long
Private Declare Function SetTextColor Lib "gdi32" (ByVal hdc As Long, ByVal _
  crColor As Long) As Long
 
Public Sub TestDesktopDC()
Dim hdc   As Long
Dim lCol  As Long
Dim tR    As RECT
 
  ' First get the Desktop DC:
  hdc = CreateDCAsNull("DISPLAY", ByVal 0&, ByVal 0&, ByVal 0&)
 
  ' Draw text on it:
  With tR
    .Left = 200
    .Top = 0
    .Right = 640
    .Bottom = 32
  End With
  lCol = GetTextColor(hdc)
  Call SetTextColor(hdc, &HFF&)
  Call DrawText(hdc, "vbAccelerator", Len("vbAccelerator"), tR, 0)
  Call SetTextColor(hdc, lCol)
 
  ' Make sure you do this to release the GDI
  ' resource:
  Call DeleteDC(hdc)
 
End Sub
 
'To test the code, add a command button to the project's form, and place the _
  following code in it's click event:
 
Private Sub Command1_Click()
  Call TestDesktopDC
End Sub