Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
 
Private Type MONITORINFO
    cbSize As Long
    rcMonitor As RECT
    rcWork As RECT
    dwFlags As Long
End Type
 
Private Declare Function MonitorFromPoint Lib "user32" (ByVal x As Long, ByVal _
  y As Long, ByVal dwFlags As Long) As Long
Private Declare Function GetMonitorInfo Lib "user32" Alias "GetMonitorInfoA" ( _
ByVal hMonitor As Long, lpmi As MONITORINFO) As Long
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
 
Private Type POINTAPI
    x As Long
    y As Long
End Type
 
Private Const MONITOR_DEFAULTTONEAREST = &H2
 
Public Sub MoveFormToMouseMonitor(frm As Form)
    Dim pt As POINTAPI
    Dim hMon As Long
    Dim mi As MONITORINFO
 
    ' Aktuelle Mausposition holen
    GetCursorPos pt
 
    ' Monitor ermitteln
    hMon = MonitorFromPoint(pt.x, pt.y, MONITOR_DEFAULTTONEAREST)
    mi.cbSize = Len(mi)
    GetMonitorInfo hMon, mi
 
    ' Formular in den sichtbaren Bereich verschieben
    frm.Move mi.rcWork.Left * Screen.TwipsPerPixelX, _
             mi.rcWork.Top * Screen.TwipsPerPixelY
End Sub

Private Sub Form_Load()
    MoveFormToMouseMonitor Me
End Sub