vb@rchiv · Tipps & Tricks · Speichern und Einlesen von Listenfeldinhalten

Rubrik: Controls · ListBox | VB-Versionen: VB4, VB5, VB6

16.01.01

Speichern und Einlesen von Listenfeldinhalten Dieser Tipp zeigt, wie man die Einträge eines Listbox-Elements in eine Datei speichert und wieder ausliest.
Autor: Heinz Prelle	Bewertung:	Views: 24.645
www.visual-basic5.de	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Dieser Tipp demonstriert, wie man den Inhalt eines Listbox-Steuerelements, d.h. die einzelnen Listen-Einträge, in eine Datei speichern und später wieder einlesen kann.

' Alle Einträge einer ListBox speichern
Public Function ListeSave(Liste As ListBox, _
  ByVal sDatei As String) As Boolean
 
  Dim F As Integer
  Dim I As Integer
 
  ' Fehlerbehandlung einschalten
  On Local Error Goto ListeSave_Error
 
  ' Datei öffnen und Einträge speichern
  F = FreeFile
  Open sDatei For Output As #F
  For I = 0 To Liste.ListCount - 1
    Print #F, Liste.List(I)
  Next I 
  Close #F
  ListeSave = True
  Exit Function
 
ListeSave_Error:
  ListeSave = False
End Function

Die Funktion ListeSave erwartet zwei Parameter:

Liste ListBox-Steuerelement, dessen Listen-Einträge gespeichert werden sollen
sDatei Dateiname inkl. Pfadangabe

Die einzelnen Einträge der Liste werden zeilenweise in die Datei geschrieben. Sollte während des Schreibvorgangs irgendein Fehler auftreten, so wird der Wert False zurückgegeben, anderfalls True.

' Listen-Elemente aus Datei lesen
Public Function ListeRead(Liste As ListBox, _
  ByVal sDatei As String) As Boolean
 
  Dim F As Integer
  Dim Zeile As String
 
  ' Fehlerbehandlung einschalten
  On Local Error Goto ListeRead_Error
 
  ' Datei öffnen und Einträge einlesen
  F = FreeFile
  Open sDatei For Input As #F
  While Not EOF(F)
    Line Input #F, Zeile
    Liste.AddItem Zeile
  Wend
  Close #F
  ListeRead = True
  Exit Function
 
ListeRead_Error:
  ListeRead = False
End Function

Die Funktion ListeRead erwartet zwei Parameter:

Liste ListBox-Steuerelement, dessen Listen-Einträge gelesen werden sollen
sDatei Dateiname inkl. Pfadangabe

Die einzelnen Einträge der Liste werden zeilenweise aus der Datei gelesen und der Liste hinzugefügt. Sollte während des Einlesens irgendein Fehler auftreten, so wird der Wert False zurückgegeben, anderfalls True.