Fensterttitel aller geöffneter IE-Instanzen ermitteln Hier zeigen wir Ihnen, wie sich die Fenstertitel aller aktuell geöffneter Internet-Explorer Instanzen ermitteln lassen
Autor:   Dieter Otter	Bewertung:	Views:  11.013
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Mit unserem heutigen Tipp möchten wir Ihnen zeigen, wie sich die Fenstertitel aller geöffneter Internet-Explorer Instanzen ermitteln lassen.

Erstellen Sie ein neues Projekt und platzieren auf die Form einen CommandButton (Command1), sowie ein ListBox-Control (List1) und fügen nachfolgenden Code in den Codeteil der Form ein:

Option Explicit
 
' zunächst die benötigten API-Deklarationen
Private Declare Function GetWindow Lib "user32" ( _
  ByVal hwnd As Long, _
  ByVal wCmd As Long) As Long
 
Private Declare Function GetClassName Lib "user32" _
  Alias "GetClassNameA" ( _
  ByVal hwnd As Long, _
  ByVal lpClassName As String, _
  ByVal nMaxCount As Long) As Long
 
Private Declare Function GetWindowTextLength Lib "user32" _
  Alias "GetWindowTextLengthA" ( _
  ByVal hwnd As Long) As Long
 
Private Declare Function GetWindowText Lib "user32" _
  Alias "GetWindowTextA" ( _
  ByVal hwnd As Long, _
  ByVal lpString As String, _
  ByVal cch As Long) As Long
 
Const GW_HWNDFIRST = 0
Const GW_HWNDNEXT = 2

Private Sub Command1_Click()
  ' alle offenen IE-Fenster ermitteln
  Dim lRetVal As Long
  Dim sClassName As String
  Dim CurHWnd As Long
  Dim nLen As Long
  Dim sBuffer As String
 
  List1.Clear
  Screen.MousePointer = 11
  CurHWnd = GetWindow(hwnd, GW_HWNDFIRST)
  Do While CurHWnd <> 0
    ' Klassennamen ermitteln
    sClassName = String$(256, " ")
    lRetVal = GetClassName(CurHWnd, sClassName, 255)
    sClassName = Left$(sClassName, InStr(sClassName, Chr$(0)) - 1)
 
    If sClassName = "IEFrame" Then
      ' Explorer-Fenster gefunden - jetzt Fenstertitel ermitteln
      nLen = GetWindowTextLength(CurHWnd)
      sBuffer = Space$(nLen + 1)
      lRetVal = GetWindowText(CurHWnd, sBuffer, Len(sBuffer))
 
      List1.AddItem Left$(sBuffer, lRetVal)
      List1.ItemData(List1.NewIndex) = CurHWnd
    End If
 
    ' Handle des nächsten Fensters
    ' 0, wenn kein weiteres Fenster vorhanden
    CurHWnd = GetWindow(CurHWnd, GW_HWNDNEXT)
  Loop
  Screen.MousePointer = 0
End Sub

Erweiterung:
Platzieren Sie zwei zusätzliche CommandButtons (Command2 und Command3) auf die Form und beschriften Sie diese mit den Texten "Wechseln zu" und "Schließen". Beim Klick auf Command2 soll die IE-Instanz des aktuell in der Liste ausgewählte Eintrags in den Vordergrund geholt werden, beim Klick auf Command3 entsprechend geschlossen werden. Hierzu sind noch folgende API-Deklarationen in den Allgemein-Teil der Form einzufügen:

Option Explicit
...
 
Private Declare Function SetForegroundWindow Lib "user32" ( _
  ByVal hwnd As Long) As Long
 
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Any) As Long
 
Const WM_SYSCOMMAND = &H112
Const SC_CLOSE = &HF060
Const LNULL = 0&

Private Sub Command2_Click()
  ' IE-Fenster in den Vordergrund holen
  SetForegroundWindow List1.ItemData(List1.ListIndex)
End Sub

Private Sub Command3_Click()
  ' IE-Fenster schließen
  With List1
    Call SendMessage(.ItemData(.ListIndex), WM_SYSCOMMAND, SC_CLOSE, LNULL)
  End With
End Sub

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.