DOS-Anwendung starten und warten bis beendet Dieser Tipp zeigt, wie Sie eine DOS-Anwendung starten und so lange warten, bis diese beendet wurde.
Autor:   Heinz Prelle	Bewertung:	Views:  44.273
www.visual-basic5.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Die Shell-Anweisung ist Ihnen sicherlich bekannt. Mit Hilfe dieser Anweisung lässt sich ein beliebiges andere Programm starten. Nachdem der Befehl ausgeführt wurde, läuft Ihre Anwendung ganz normal weiter. In manchen Fällen mag dies auch sinnvoll sein. Oftmals aber sollte die eigene Anwendung jedoch so lange warten, bis das gestartete Programm beendet wurde. Dies lässt sich allerding nur über die Windows-API realisieren. Der nachfolgende Tipp zeigt wie's geht.

Anmerkung: Dieser Tipp funktioniert nur in Verbindung mit dem Aufruf von DOS-Anwendungen

' zunächst die benötigten API-Deklarationen
Private Declare Function CloseHandle Lib "kernel32" ( _
  ByVal hObject As Long) As Long
 
Private Declare Function OpenProcess Lib "kernel32" ( _
  ByVal dwDesiredAccess As Long, _
  ByVal bInheritHandle As Long, _
  ByVal dwProcessId As Long) As Long
 
Private Declare Function WaitForSingleObject Lib "kernel32" ( _
  ByVal hHandle As Long, _
  ByVal dwMilliseconds As Long) As Long
 
Private Const INFINITE = &HFFFF
Private Const SYNCHRONIZE = &H100000
 
' Warten bis Anwendung beendet
Public Sub AppStartAndWait(ByVal sFile As String, _
  ByVal wStyle As VbAppWinStyle)
 
  ' Parameterbeschreibung
  ' sFile:  Anwendung, die gestartet werden soll
  ' wStyle: Darstellungsart des Anwendungsfensters
 
  Dim lRetVal As Long
  Dim lHandle As Long
  Dim lRet As Long
 
  lRetVal = Shell(sFile, wStyle)
  If lRetVal <> 0 Then
    lHandle = OpenProcess(SYNCHRONIZE, 0, lRetVal)
    If lHandle <> 0 Then
      lRet = WaitForSingleObject(lHandle, INFINITE)
      CloseHandle (lHandle)
    End If
  End If
End Sub

Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.