vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Controls · DataGrid & DataGridView   |   VB-Versionen: VB2005, VB2008, VB201029.06.11
Keine Daten für DatagridView- Mitteilung

Im Anzeigebereich des Datagridview kan ein Text angezeigt werden, wenn das DGV gerade keine Daten enthält.

Autor:   Dietrich HerrmannBewertung:  Views:  8.945 
ohne HomepageSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Wendet man ein datengebundenes DatagridView an und filtert man die Daten, kann es schon manchmal vorkommen, dass zu dem Filter keine Daten existieren und demzufolge das DGV auch keine Daten anzeigen kann. Man könnte dies mittels Messagebox dem User mitteilen, ich habe aber mit der unten angegebenen Funktion eine Möglichkeit, einen individuellen Text direkt in den Anzeigebereich des DGV zu schreiben.

Zunächst:

Imports System.Drawing, System.Drawing.Drawing2D

Ich habe für die Verwendung der Funktion noch zwei Enumerationen vereinbart:

Public Enum dgvHorizontalAlign
  Left
  Center
  Right
End Enum
 
Public Enum dgvVerticalAlign
  Top
  Center
  Bottom
End Enum

Und hier die Funktion selbst:

''' <summary>
''' Textausgabe im DatagridView-Bereich, wenn keine Daten angezeigt werden können
''' </summary>
''' <param name="theDGV">das DatagridView</param>
''' <param name="e">PaintEventArgs des Paint-Ereignisses des DGV</param>
''' <param name="emptyColor">Farbe für den Text</param>
''' <param name="addingPoint">zusätzliche Verschiebung in der Ausrichtung</param>
''' <param name="emptyDataText">der auszugebende Text</param>
''' <param name="emptyFont">Font für den Text</param>
''' <param name="emptyDataTextVerticalAlign">vertikale Ausrichtung des Texts</param>
''' <param name="emptyDataTextHorizontalAlign">horizontale Ausrichtung des Texts</param>
''' <remarks >Die Ausrichtung des Texts bezieht sich auf das Anzeigerechteck des DGV.
''' Die Funktion muss im Paint-Ereignis des DGV angewendet werden.</remarks>
Public Sub ShowDGVHasNoDataText(ByVal theDGV As DataGridView, ByVal e As PaintEventArgs, _
  ByVal emptyColor As Color, _
  ByVal addingPoint As Point, _
  Optional ByVal emptyDataText As String = "Keine Daten vorhanden!", _
  Optional ByVal emptyFont As Font = Nothing, _
  Optional ByVal emptyDataTextVerticalAlign As dgvVerticalAlign = dgvVerticalAlign.Top, _
  Optional ByVal emptyDataTextHorizontalAlign As dgvHorizontalAlign = dgvHorizontalAlign.Left)
 
  Dim x, y As Short
 
  If theDGV.RowCount > 1 OrElse (theDGV.RowCount = 1 And Not theDGV.AllowUserToAddRows) Then _
    emptyDataText = "" ' wird ausgegeben, wenn Daten vorhanden
 
  With e.Graphics
    ' Textgröße gemäß Font ermitteln
    Dim textSize As SizeF = .MeasureString(emptyDataText, emptyFont)
 
    ' setzen der X-Koordinate des Textes
    Select Case emptyDataTextHorizontalAlign
      Case dgvHorizontalAlign.Left
        x = 0
      Case dgvHorizontalAlign.Center
        x = (theDGV.Width - textSize.Width) / 2
      Case dgvHorizontalAlign.Right
        x = theDGV.Width - textSize.Width
    End Select
 
    ' setzen der Y-Koordinate des Textes
    Select Case emptyDataTextVerticalAlign
      Case dgvVerticalAlign.Top
        y = 0
      Case dgvVerticalAlign.Center
        y = (theDGV.Height - textSize.Height) / 2
      Case dgvVerticalAlign.Bottom
        y = theDGV.Height - textSize.Height
    End Select
 
    ' Ausgabe des Textes an vorgegebener Position
    If emptyColor.Name = "0" Then emptyColor = Color.Black
    Dim brush As New SolidBrush(emptyColor)
    .DrawString(emptyDataText, emptyFont, brush, New Point(x, y) + addingPoint)
  End With
End Sub

Aufrufbeispiel:
In diesem Beispiel werden gleich zwei verschiedene DatagridViews angesprochen...

Private Sub DatagridView1_Paint(ByVal sender As Object, _
  ByVal e As PaintEventArgs) Handles DatagridView1.Paint, DatagridView2.Paint
 
  ShowDGVHasNoDataText(sender, e, Color.Red, New Point(100, 0), , _
    New Font("", 16, FontStyle.Bold Or FontStyle.Underline Or FontStyle.Italic), _
    dgvVerticalAlign.Center, dgvHorizontalAlign.Left)
End Sub



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.