vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#

https://www.vbarchiv.net
Rubrik: Datum/Zeit und Timer · Datums- und Zeit-Funktionen   |   VB-Versionen: VB2008, VB2010, VB201222.07.13
Zwei Funktionen zu DateTime

Die erste Funktion ermittelt zu einem Monat entweder alle Tage ohne die Wochendtage oder nur die Wochenendtage. Die zweite Funktion ermittelt alle Kalenderwochennummern zu einem Monat.

Autor:   Dietrich HerrmannBewertung:  Views:  7.369 
ohne HomepageSystem:  WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Für spezielle grafische Darstellungen von Daten (Charts) benötigte ich die von den genannten Funktionen erstellten Ergebnisse - und möglicherweise können sie auch in anderen Fällen nützlich sein.

Bei beiden Funktionen wird als Parameter ein "Referenzdatum" eingegeben, also ein Datum aus dem betreffenden Monat. Die erste Funktion getDaysOfMonthWOWeekends ermittelt zu dem Monat/Jahr, die im Referenzdatum enthalten sind, entweder:

  • alle Tage des betreffenden Monats, die nicht Wochenendtage sind oder
  • alle Tage des Monats, die die Wochenendtage sind.

Welches Ergebnis bereitgestellt wird, steuert der Parameter invert. Das Ergebnis wird in einem Array zurückgegeben.

Die erste Funktion:

''' <summary>
''' Tage eines Monats ohne Wochenendtage oder nur Wochenendtage eines Monats
''' </summary>
''' <param name="datum">ein Referenzdatum des Monats</param>
''' <param name="invert">False.. Tage ohne WE-Tage; TRUE.. nur die WE-Tage</param>
''' <returns>ein Array der Tagesdaten</returns>
Public Function getDaysOfMonthWOWeekends(datum As DateTime, _
  Optional invert As Boolean = False) As Date()
 
  Dim d, j As Short, w, wa As Boolean
  Dim days As Short = TageDesMonats(datum)
  Dim actDat, temp() As Date
 
  d = 1 : j = 0
  For i As Short = 0 To days - 1
    actDat = DateSerial(datum.Year, datum.Month, d)
    w = (actDat.DayOfWeek = DayOfWeek.Saturday OrElse actDat.DayOfWeek = DayOfWeek.Sunday)
    If invert Then wa = w Else wa = Not w
    If wa Then
      ReDim Preserve temp(j)
      temp(j) = actDat
      j += 1
    End If
    d += 1
  Next 
  Return temp
End Function

Die zweite Funktion getAllWeeknumbersOfMonth ermittelt zu dem Monat/Jahr, die im Referenzdatum enthalten sind, alle Kalenderwochennummern. Es werden in einem zweidimensionalen Array der jeweils erste Tag der Kalenderwoche und die Wochennummer ausgegeben.

''' <summary>
''' Alle Wochennummern eines Monats ermitteln
''' </summary>
''' <param name="datum">ein Referenzdatum des Monats</param>
''' <returns>ein zweidim. Array enthält jeweils erster Tag der Woche, Wochennummer</returns>
Public Function getAllWeeknumbersOfMonth(datum As DateTime) As Short(,)
  Dim j, d, dd, lastW, actW As Short, actDat As Date
  Dim days As Short = TageDesMonats(datum)
  Dim temp(1, 0) As Short
 
  j = -1
  For d = 1 To days
    actDat = DateSerial(datum.Year, datum.Month, d)
    actW = DateToWeek(actDat)
    If lastW = 0 OrElse lastW <> actW Then
      j += 1
      dd = d
    End If
    ReDim Preserve temp(1, j)
    temp(0, j) = dd
    temp(1, j) = actW
    lastW = actW
  Next 
  Return temp
End Function

Nun noch die in beiden Funktionen benötigte Hilfsfunktion zur Ermittlung der Anzahl der Tage des Monats:

''' <summary>
''' Ermitteln der Anzahl der Tage eines Monats oder auch letzter Tag des Monats
''' </summary>
''' <param name="datum">ein Referenzdatum des Monats</param>
''' <returns>Anzahl bzw. Tag</returns>
Public Function TageDesMonats(ByVal datum As Date) As Short
  Dim dDate As Date = DateSerial(datum.Year, datum.Month, 1)
  Dim d As Date = DateAdd(DateInterval.Month, 1, dDate)
 
  d = DateAdd(DateInterval.Day, -1, d)
  Return d.Day
End Function



Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
 
Copyright ©2000-2024 vb@rchiv Dieter OtterAlle Rechte vorbehalten.


Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.