Dim ch As New System.Windows.Forms.DataVisualization.Charting.Chart _
  With {.Parent = Me, .Height = 400, .Width = 400}

  Private Sub CreateChart(ByVal Columnname As String)
 
      'Datatable für Spaltendaten
      Dim dt As New DataTable
      dt.Columns.Add("ID", GetType(Integer))
      dt.Columns.Add(Columnname, GetType(Double))
 
      'Ermittlung des Spaltenindex
      Dim columnindex As Integer = -1
      For i As Integer = 0 To lv.Columns.Count - 1
            If lv.Columns(i).Text.ToLower = Columnname.ToLower Then _
               columnindex = i
      Next i
      If columnindex = -1 Then Exit Sub
 
      'Übertragung der Listview-Spalte in die Table
      For i As Integer = 0 To lv.Items.Count - 1
         dt.Rows.Add _
          ({i + 1, CDbl(lv.Items(i).SubItems(columnindex).Text)})
      Next i
 
      With ch
        .DataSource = dt
        .Titles.Clear()
        .Titles.Add(Columnname)
 
        .ChartAreas.Clear()
        .ChartAreas.Add("Base")
 
        With .ChartAreas(0)
           .AxisX.MajorGrid.LineDashStyle = _
                DataVisualization.Charting.ChartDashStyle.Dot
           .AxisY.MajorGrid.LineDashStyle = _
                DataVisualization.Charting.ChartDashStyle.Dash
        End With
 
        With .Series
           .Clear()
           .Add(Columnname)
        End With
 
        With .Series(0)
           .ChartArea = "Base"
 
           'Datenbindung an Datatable
           .XValueMember = dt.Columns(0).ColumnName
           .YValueMembers = dt.Columns(1).ColumnName
 
           .ChartType = DataVisualization.Charting.SeriesChartType.Point
           .Palette = DataVisualization.Charting.ChartColorPalette.Grayscale
        End With
      End With
  End Sub