''' <summary>String-Einträge im Listview in CSV-Datei schreiben</summary>
''' <param name="lv">Listview-Control</param>
''' <param name="filename">Pfad und Name der Ausgabedatei</param>
''' <param name="AllowOverwrite">Darf die Ausgabedatei ggf. überschrieben 
' werden</param>
''' <returns>Alles OK?</returns>
Private Function ListViewToCsv(ByVal lv As ListView, ByVal filename As String, _
                  Optional ByVal AllowOverwrite As Boolean = False) As Boolean
 
   Const tz As Char = ";"c 'Feld-Trennzeichen
   Const rp As Char = ","c 'Ersatzzeichen 
 
   If lv Is Nothing OrElse lv.Items.Count = 0 Then Return Nothing
 
   Try
      filename = _
        IO.Path.ChangeExtension(filename, ".csv") 'Extension sicherstellen
 
      If IO.File.Exists(filename) Then
         If AllowOverwrite = False Then
            Return False
         Else
            IO.File.Delete(filename)
         End If
      End If
 
 
      Using sw As New IO.StreamWriter(filename) 'Ausgabestream
 
         'Maximale Anzahl von Subitems im Listview bestimmen
         Dim sic As Integer = 0
         For i As Integer = 0 To lv.Items.Count - 1
            sic = Math.Max(lv.Items(i).SubItems.Count, sic)
         Next i
 
         Dim line As New System.Text.StringBuilder 'Ausgabezeile, Item
 
         'Itemschleife
         For i As Integer = 0 To lv.Items.Count - 1
            line.Clear()
 
            'Item und ggf. Subitems
            For si As Integer = 0 To lv.Items(i).SubItems.Count - 1
               line.Append(lv.Items(i).SubItems(si).Text.Replace(tz, rp))
               line.Append(tz)
            Next si
 
            For si As Integer = lv.Items(i).SubItems.Count To sic - 1
                line.Append(tz) 'ggf. Zeile mit Leerfeldern auffüllen
            Next si
 
            'sw.WriteLine(line.ToString.TrimEnd(tz)) 'Zeile schreiben
            sw.WriteLine(line.ToString)
         Next i
      End Using
 
      'Alles OK
      Return True
   Catch
      'OOOPs
      Return False
   End Try
 
End Function