Sub Example_ScreenUpdating()
  ScreenUpdating(FindWindowHandle(Application)) = True 'or False
End Sub
 
Property Let ScreenUpdating(Optional ByVal hWnd As Long, ByVal State As Boolean)
  If Not State Then
    LockWindowUpdate hWnd
  Else
    LockWindowUpdate False
    UpdateWindow hWnd
  End If
End Property
 
 
 
Function FindWindowHandle(ByVal App As Object, Optional ByVal Caption As _
  String) As Long
  If App Is Nothing Then
    FindWindowHandle = FindWindow(vbNullString, Caption)
  Else
    On Error Resume Next
    Select Case App.Name
      Case "Microsoft Access"
        'Caption = App.Name
        FindWindowHandle = FindWindow("OMAIN", Caption)
      Case "Microsoft Excel"
        'Caption = App.Caption
        FindWindowHandle = FindWindow("XLMAIN", Caption)
      Case "Microsoft PowerPoint"
        Select Case Val(Application.Version)
          Case 8
            FindWindowHandle = FindWindow("PP97FrameClass", Caption)
          Case 9 To 12
            'Caption = App.Caption & " - [" & App.ActiveWindow.Caption & "]"
            FindWindowHandle = FindWindow("PP" & Val(Application.Version) & _
              "FrameClass", _
              Caption)
          Case Else
            'Caption = App.Caption
            FindWindowHandle = FindWindow("PPTFrameClass", Caption)
        End Select
      Case "Microsoft Word"
        'Caption = App.ActiveWindow.Caption & " - " & App.Caption
        FindWindowHandle = FindWindow("OPUSAPP", Caption)
      Case "Outlook"
        'Caption = Application.ActiveExplorer.Caption
        FindWindowHandle = FindWindow("rctrl_renwnd32", Caption)
      Case Else
        'Userform
        'Caption = App.Caption
        If Val(Application.Version) >= 9 Then
          FindWindowHandle = FindWindow("ThunderDFrame", Caption)
        Else
          FindWindowHandle = FindWindow("ThunderXFrame", Caption)
        End If
    End Select
  End If
End Function