vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevAniGif - als kostenlose Vollversion auf unserer vb@rchiv CD Vol.5  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2014
 
zurück
Rubrik: Controls · MSFlexGrid/DataGrid   |   VB-Versionen: VB612.11.04
Bild im FlexGrid in korrekter Gr??e anzeigen

Wie man im MSFlexGrid-Control ein Bild in seiner korrekten Gr??e anzeigen kann, das erfahren Sie hier.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  14.409 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8 Beispielprojekt auf CD 

Folgendes Szenario: Sie verwenden das MSFlexGrid-Control und möchten in einer bestimmten Zelle zusätzlich ein Bild anzeigen. Das Bild selbst befindet sich hierbei entweder in einem ImageList-Control oder soll bspw. direkt aus einer Icon-Datei geladen werden.

' Bild aus ImageList in FlexGrid anzeigen
With MSFlexGrid1
  .Row = 1
  .Col = 1
  Set .CellPicture = ImageList1.ListImages(1).Picture
End With
' Bild aus Datei in FlexGrid anzeigen
With MSFlexGrid1
  .Row = 1
  .Col = 1
  Set .CellPicture = LoadPicture(App.Path & "\email.ico")
End With

Egal, wie man's auch anstellt: das kleine 16x16 Icon wird im FlexGrid immer viel zu groß dargestellt

Nachfolgend möchten wir Ihnen eine Prozedur vorstellen, mit der sich Bilder im FlexGrid-Control ab sofort in der gewünschten Größe anzeigen lassen!

' Bild im FlexGrid in beliebiger Größe anzeigen
Public Sub flx_ShowPicture(oForm As Object, _
  oGrid As Object, _
  oPicture As StdPicture, _
  ByVal nRow As Long, ByVal nCol As Long, _
  Optional ByVal nWidth As Long = 16, _
  Optional ByVal nHeight As Long = 16, _
  Optional ByVal nBackColor As Long = vbWhite)
 
  Dim oPicBox As Control
 
  ' temporäre PictureBox auf der Form erstellen
  On Error Resume Next
  Set oPicBox = oForm.Controls("tmpPictureBox")
  If Err <> 0 Then
    Set oPicBox = oForm.Controls.Add("VB.PictureBox", "tmpPictureBox")
    oPicBox.BorderStyle = 0
  End If
  On Error GoTo 0
 
  With oGrid
    ' Zeile und Spalte festlegen
    .Row = nRow
    .Col = nCol
 
    ' Bild in die PictureBox zeichnen
    With oPicBox
      .BackColor = nBackColor
      .Width = nWidth * Screen.TwipsPerPixelX
      .Height = nHeight * Screen.TwipsPerPixelY
      .AutoRedraw = True
      .PaintPicture oPicture, 0, 0, .ScaleWidth, .ScaleHeight
      .AutoRedraw = False
    End With
 
    ' Bild der Zelle im FlexGrid zuweisen
    Set .CellPicture = oPicBox.Image
  End With
 
  ' temporäre PictureBox wieder entfernen
  oForm.Controls.Remove "tmpPictureBox"
End Sub

Aufrufbeispiel:

' Bild aus ImageList in FlexGrid anzeigen
flx_ShowPicture Me, MSFlexGrid1, ImageList1.ListImages(1).Picture, 1, 1
' Bild aus Datei in FlexGrid anzeigen
flx_ShowPicture Me, MSFlexGrid1, LoadPicture(App.Path & "\email.ico", 1, 1

Über die optionalen Parameter nWidth und nHeight lässt sich die Größe festlegen, sollte sie von 16x16 abweichen. Weiterhin kann über den letzten optionalen Parameter die gewünschte Hintergrundfarbe angegeben werden.
 

Dieser Tipp wurde bereits 14.409 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2014 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.

Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel