Anzahl Dimensionen eines Arrays ermitteln Eine Funktion, die mit Hilfe des Windows API schnell die Anzahl Dimensionen eines beliebigen Arrays ermittelt und zurückgibt.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  16.253
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 4 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.0 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Möchte man die Anzahl Dimensionen eines Arrays in VB ermitteln, sucht man hier vergebens nach einer entsprechenden Funktion. Mittels der allseits bekannten UBound-Funktion lässt sich lediglich die Größe einer einzelnen Array-Dimensionen ermitteln (Anzahl Elemente der Dimension).

Wie schon so oft hilft uns hier wieder einmal nur das Windows-API aus der Klemme.

Nachfolgende Funktion ermittelt die Anzahl Dimensionen des übergebenen Arrays und gibt diese entsprechend zurück. Für nicht initialisierte Arrays, d.h. Arrays die keinerlei Dimension enthalten, gibt die Funktion 0 zurück.

Option Explicit
 
' benötigte API-Deklaration
Private Declare Sub CopyMemory Lib "kernel32" _
  Alias "RtlMoveMemory" ( _
  Destination As Any, _
  Source As Any, _
  ByVal Length As Long)

Public Function GetArrayDim(ByRef vArray As Variant) As Integer
  ' Handelt es sich überhaupt um ein Array?
  Dim DimCount As Integer
 
  DimCount = -1
  If IsArray(vArray) Then
    Dim vPtr As Long
 
    DimCount = 0
    vPtr = VarPtr(vArray) + 8
    CopyMemory vPtr, ByVal vPtr, 4
    CopyMemory vPtr, ByVal vPtr, 4
    If vPtr Then CopyMemory DimCount, ByVal vPtr, 2
  End If
  GetArrayDim = DimCount
End Function

Beispiele:

' Arrays in verschiedenen Dimensionen erstellen
Dim array1(10) As String
Dim array2(10, 5) As Long
Dim array3(2 To 8, 1 To 6, 3 To 9) As Byte
Dim array4() As Variant
 
' Dimensionen ermitteln
Debug.Print GetArrayDim(array1)  ' gibt 1 zurück
Debug.Print GetArrayDim(array2)  ' gibt 2 zurück
Debug.Print GetArrayDim(array3)  ' gibt 3 zurück
Debug.Print GetArrayDim(array4)  ' gibt 0 zurück