' Benötigte API-Deklarationen
Private Declare Function SetLocaleInfo Lib "kernel32" _
  Alias "SetLocaleInfoA" ( _
  ByVal Locale As Long, _
  ByVal LCType As Long, _
  ByVal lpLCData As String) As Long
 
Private Declare Function PostMessage Lib "user32" _
  Alias "PostMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Long) As Long
 
Private Declare Function GetSystemDefaultLCID Lib "kernel32" () As Long
 
Private Const LOCALE_SSHORTDATE = &H1F
Private Const LOCALE_STIMEFORMAT = &H1003
Private Const WM_SETTINGCHANGE = &H1A
Private Const HWND_BROADCAST = &HFFFF&
 
Public Function SetNewTimeFormat(ByVal sDateFormat As String, _
  Optional ByVal sTimeFormat As String = "") As Boolean
 
  Dim nLCID As Long
  Dim bResult As Boolean
 
  nLCID = GetSystemDefaultLCID()
 
  ' Neues Datumformat setzen
  bResult = (SetLocaleInfo(nLCID, LOCALE_SSHORTDATE, sDateFormat) <> 0)
  If bResult Then
    ' System über die Änderung benachrichtigen
    PostMessage HWND_BROADCAST, WM_SETTINGCHANGE, 0, 0
  End If
 
  If bResult And Len(sTimeFormat) > 0 Then
    ' Neues Zeitfroamt setzen
    bResult = (SetLocaleInfo(nLCID, LOCALE_STIMEFORMAT, sTimeFormat) <> 0)
    If bResult Then
      ' System über die Änderung benachrichtigen
      PostMessage HWND_BROADCAST, WM_SETTINGCHANGE, 0, 0
    End If
  End If
 
  SetNewTimeFormat = bResult
End Function

SetNewTimeFormat "dd.MM.yyyy"

SetNewTimeFormat "dd.MM.yyyy", "HH:mm:ss"

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de