Public Sub ColWidthProzent(Grid As sevDataGrid.Grid, _
                           ByVal ColWidthArray As Variant)
 
'Prüfung, ob Arrays übergeben wurden
    If Not IsArray(ColWidthArray) Then Exit Sub
 
    Dim MaxW        As Integer              'maximal verfügbare Breite
    Dim sbWidth     As Integer              'Breite Scrollbar
    Dim fcWidth     As Integer              'Breite FixedCol
    Dim glWidth     As Integer              'Breite Gridlines
    Dim n%, i%
    Dim ColW        As Long
 
    With Grid
 
'maximal verfügbare Breite berechnen
'und in der Variable MaxW speichern
 
        If .FixedCol Then _
            fcWidth = .FixedColWidth Else fcWidth = 0
        If .ScrollBars = SB_BOTH _
        Or .ScrollBars = SB_VERTICAL _
        Or .ScrollBars = SB_AUTO Then _
            sbWidth = 500 Else sbWidth = 0
        If .GridLines = GRID_BOTH _
        Or .GridLines = GRID_VLINE Then _
            glWidth = (.Cols * .CellSpacing) Else glWidth = 0
 
        MaxW = .Width - fcWidth - sbWidth - glWidth
 
'Spaltenbreiten berechnen und einstellen
 
        ColW = 0
        For n = 1 To .Cols
            If ColWidthArray(n - 1) > 0 Then
                .Columns(n).Width = (MaxW * ColWidthArray(n - 1)) \ 100
                 ColW = ColW + .Columns(n).Width
            Else
                .Columns(n).Width = 0
                .Columns(n).Visible = False
            End If
        Next n
 
'Letzte sichtbare Spalte anpassen
 
        For n = .Cols To 1 Step -1
            If .Columns(n).Visible Then
                 ColW = ColW - .Columns(n).Width
                .Columns(n).Width = MaxW - ColW
                 Exit For
            End If
        Next n
 
    End With
 
End Sub