Public Sub ColWidthProzent(Grid As sevDataGrid.Grid, _
  ByVal ColWidthArray As Variant)
 
  ' Prüfung, ob Arrays übergeben wurden
  If Not IsArray(ColWidthArray) Then Exit Sub
 
  Dim MaxW        As Integer              ' maximal verfügbare Breite
  Dim n%, i%
  Dim ColW        As Long
 
  ' maximal verfügbare Breite berechnen
  ' und in der Variable MaxW speichern
  With Grid
 
     ' FixedCol?
     MaxW = .Width - 4 * Screen.TwipsPerPixelX
     If .FixedCol Then MaxW = MaxW - .FixedColWidth
 
     ' ScrollBar?
     If .ScrollBars <> SB_HORIZONTAL And .ScrollBars <> SB_HORIZONTAL Then _
       MaxW = MaxW - GetSystemMetrics(SM_CXVSCROLL) * Screen.TwipsPerPixelX
 
     ' GridLines?
     n = 0
     For i = 1 To .Cols
       If .Columns(i).Visible Then
         n = n + 1
         MaxW = MaxW - (.CellSpacing * 2) * Screen.TwipsPerPixelX
         If n > 1 Then MaxW = MaxW - (.GridLineWidth * Screen.TwipsPerPixelX)
       End If
     Next i
 
     ' Spaltenbreiten berechnen und einstellen
     ColW = 0
     For n = 1 To .Cols
       If ColWidthArray(n - 1) > 0 Then
         .Columns(n).Width = (MaxW * ColWidthArray(n - 1)) \ 100
         ColW = ColW + .Columns(n).Width
       Else
         .Columns(n).Visible = False
       End If
     Next n
 
    ' Letzte sichtbare Spalte anpassen
    For n = .Cols To 1 Step -1
      If .Columns(n).Visible Then
        ColW = ColW - .Columns(n).Width
        .Columns(n).Width = MaxW - ColW
        Exit For
      End If
    Next n
 
  End With
End Sub

_________________________
Professionelle Entwicklerkomponenten
www.tools4vb.de