Imports System.Runtime.InteropServices
 
Public Class Form1
 
#Region "Api-Deklarationen"
    Private Delegate Function EnumWindowsProcDele( _
            ByVal hwnd As IntPtr, _
            ByVal lParam As IntPtr) As Boolean
 
    Private Declare Function EnumWindows Lib "user32.dll" ( _
      ByVal lpEnumFunc As EnumWindowsProcDele, _
      ByVal lParam As IntPtr) As Boolean
 
    Private Declare Function GetDesktopWindow Lib "user32.dll" () As IntPtr
 
    Private Declare Function GetWindowText Lib "user32.dll" Alias _
      "GetWindowTextA" ( _
      ByVal hwnd As IntPtr, _
      ByVal lpString As System.Text.StringBuilder, _
      ByVal cch As Int32) As Int32
 
    Private Declare Function GetWindowTextLength Lib "user32.dll" Alias _
      "GetWindowTextLengthA" ( _
      ByVal hwnd As IntPtr) As Int32
 
#End Region
 
    'Klasse, um sich Infos zu Fenstern zu merken
    Private Class EnumWindowsInfo
        Public Match As String          'Gibt an, welche Fenster gefunden 
        ' werden sollen
        Public [Handles] As IntPtr()    'Gibt die Handles der Fenster zurück
        Public Text As String()         'Gibt den Titel der Fenster zurück
    End Class
 
    Private Sub cmdFindWindows_Click(ByVal sender As System.Object, ByVal e As _
      System.EventArgs) _
        Handles cmdFindWindows.Click
        Try
            'Neue Info-Klasse machen
            Dim info As New EnumWindowsInfo
            '...und Member initialisieren
            info.Handles = New IntPtr() {}
            info.Match = "F*"
            info.Text = New String() {}
            'Die Klasse pinnen, damit sie vom GC nicht verschoben wird
            Dim gch As GCHandle = GCHandle.Alloc(info, GCHandleType.Normal)
            Try
                'Das GCHandle als IntPtr holen, weil die API-Funktion das 
                ' braucht
                Dim lParam As IntPtr = GCHandle.ToIntPtr(gch)
                Dim d As New EnumWindowsProcDele(AddressOf EnumWindowsProc)
                Dim hwndDeskTop As IntPtr = GetDesktopWindow
                'Fenster enummerieren lassen
                EnumWindows(d, lParam)
 
                Debug.WriteLine("ERGEBNIS:")
                For idx As Integer = 0 To info.Handles.Length - 1
                    Debug.WriteLine("Fensterhandle: " & info.Handles( _
                      idx).ToString & _
                                    "; Text: " & info.Text(idx))
                Next
            Catch ex As Exception
                Debug.WriteLine(ex.ToString)
            Finally
                gch.Free()
            End Try
 
        Catch ex As Exception
            MsgBox(ex.ToString)
        End Try
    End Sub
 
    Private Function EnumWindowsProc(ByVal hwnd As IntPtr, ByVal lParam As _
      IntPtr) As Boolean
        Try
            Debug.Write("In EnumWindowsProc ")
            Dim ret As Integer
            'Die Länge des Fenstertitels holen
            ret = GetWindowTextLength(hwnd)
            If ret > 0 Then
                'Den Titeltext des Fensters holen
                Dim sb As New System.Text.StringBuilder(ret)
                ret = GetWindowText(hwnd, sb, ret)
                Dim txt As String = sb.ToString
                'Das GCHandle zurückholen 
                Dim gch As GCHandle = GCHandle.FromIntPtr(lParam)
                'Jetzt das im GCHandle allozierte Objekt holen
                Dim info As EnumWindowsInfo = CType(gch.Target, EnumWindowsInfo)
 
                Debug.WriteLine("Fenster mit Text " & txt)
                'Vergleich, ob der Text dem Gesuchten entspricht und ggf. merken
                If txt Like info.Match Then
                    ReDim Preserve info.Handles(info.Handles.Length)
                    info.Handles(info.Handles.Length - 1) = hwnd
                    ReDim Preserve info.Text(info.Text.Length)
                    info.Text(info.Text.Length - 1) = txt
                End If
            Else
                Debug.WriteLine("Fenster ohne Text")
            End If
            Return True
        Catch ex As Exception
            Debug.WriteLine(ex.ToString)
        End Try
    End Function
End Class