Public Class frmDGVBOX
 
    Dim dt As New DataTable
    Dim bs As New BindingSource
 
    Dim WithEvents dgv As New DataGridView With _
        {.Parent = Me, .DataSource = bs, .Width = 320}
 
    Dim tbo As New List(Of TextBox)
 
    Private Sub frmDGVBOX_Load(sender As System.Object, _
         e As System.EventArgs) Handles MyBase.Load
 
        'Textboxen erstellen und positionieren
        For i As Integer = 0 To 3
            tbo.Add(New TextBox)
            With tbo(i)
                .Top = i * 40 : .Left = 350 : .Parent = Me
            End With
        Next i
 
        'Testdaten
        With dt
            With .Columns
                .Add("ID", GetType(Integer))
                .Add("Text", GetType(String))
            End With
            For i As Integer = 1 To 30
                With .Rows
                    .Add(i, "Datensatz " & CStr(i))
                End With
            Next i
        End With
 
        'Bindung
        bs.DataSource = dt
    End Sub
 
    Private Sub dgv_CellClick(sender As Object, _
        e As System.Windows.Forms.DataGridViewCellEventArgs) Handles _
        dgv.CellClick
 
        If e.RowIndex < 0 Then Exit Sub
 
        Dim vl As Object = CType(bs(e.RowIndex), DataRowView).Row("ID")
        If TypeOf vl Is Integer Then
            Dim id As String = CStr(vl)
            Dim ok As Boolean = False
            For i As Integer = 0 To tbo.Count - 1
                If tbo(i).Text = String.Empty Then
                    tbo(i).Text = id : ok = True : Exit For
                End If
            Next i
            If Not ok Then
                For i As Integer = 0 To tbo.Count - 2
                    tbo(i).Text = tbo(i + 1).Text
                Next i
                tbo(tbo.Count - 1).Text = id
            End If
        End If
    End Sub
End Class