Imports System.Globalization
 
Public Class Form1
   Private bs As New BindingSource
 
   Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) _
     Handles MyBase.Load
      bs.DataSource = getECBCurrencyExchanges( _
      "http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml")
      Me.DataGridView1.DataSource = bs
   End Sub
 
 
   Private Function getECBCurrencyExchanges(ByVal WebAddress As String) As _
     IQueryable
      Try
         Dim xr As XElement = XElement.Load(WebAddress)
         Dim xn As XNamespace = xr.Attribute("xmlns").Value
 
         Dim xECBs = From ECB In xr.Descendants(xn + "Cube") _
                     Where ECB.Attribute("currency") IsNot Nothing _
                     AndAlso ECB.Attribute("rate") IsNot Nothing _
                     Select Currency = ECB.Attribute("currency").Value, _
                            DisplayName = GetCurrencyName(ECB.Attribute( _
                            "currency").Value), _
                            Rate = Double.Parse(ECB.Attribute("rate").Value, _
                            New CultureInfo("en-US"))
 
         Return xECBs.AsQueryable
      Catch ex As Exception
         Throw ex
      End Try
   End Function
 
   Private Function GetCurrencyName(ByVal isoCode As String) As String
      Dim cultures As CultureInfo() = CultureInfo.GetCultures( _
        CultureTypes.SpecificCultures)
 
      For Each ci As CultureInfo In cultures
         Dim ri As New RegionInfo(ci.LCID)
         If ri.ISOCurrencySymbol = isoCode Then
            Return ci.DisplayName
         End If
      Next
      Return String.Empty
   End Function
End Class

Gru?
---------------------------------------------------
Snoopy sagt - vb@rchiv find ich gut...
Schon gesehen? OSMMapViewer V2 Control