Imports System.Globalization
 
' ECB Struktur
Public Structure ECBType
   Public ECBCurrency As String
   Public ECBRate As String
   Public DisplayName As String
End Structure
 
 
Public Class ECBExchanges
   Public Function getECBCurrencyExchanges(ByVal WebAddress As String) As List( _
     Of ECBType)
      Try
         Dim xr As XElement = XElement.Load(WebAddress)
         Dim xn As XNamespace = xr.Attribute("xmlns").Value
 
         Dim xECBs = From ECB In xr.Descendants(xn + "Cube") _
                     Where ECB.Attribute("currency") IsNot Nothing _
                     AndAlso ECB.Attribute("rate") IsNot Nothing _
                     Select New ECBType With { _
                        .ECBCurrency = ECB.Attribute("currency").Value, _
                        .ECBRate = ECB.Attribute("rate").Value, _
                        .DisplayName = CurrencyName(.ECBCurrency)}
 
         Return xECBs.ToList
      Catch ex As Exception
         Throw ex
      End Try
   End Function
 
   Private Function CurrencyName(ByVal isoCode As String) As String
      Dim cultures As CultureInfo() = CultureInfo.GetCultures( _
        CultureTypes.SpecificCultures)
 
      For Each ci As CultureInfo In cultures
         Dim ri As New RegionInfo(ci.LCID)
         If ri.ISOCurrencySymbol = isoCode Then
            Return ci.DisplayName
         End If
      Next
      Return String.Empty
   End Function
End Class

   Private MyECB As New ECBExchanges
 
   Dim ECBList As List(Of ECBType) = MyECB.getECBCurrencyExchanges( _
     "http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml")

Gru?
---------------------------------------------------
Snoopy sagt - vb@rchiv find ich gut...
Schon gesehen? OSMMapViewer V2 Control