Imports System.Globalization
 
Public Class ECBItem
   Public Property Currency As String
   Public Property DisplayName As String
   Public Property Rate As Double
End Class
 
 
Public Class clsECB
   Inherits ObjectModel.ObservableCollection(Of ECBItem)
 
   Public Sub LoadExchanges()
      Try
         Dim xr As XElement = XElement.Load( _
           "http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml")
         Dim xn As XNamespace = xr.Attribute("xmlns").Value
 
         Dim xECBs = From ECB In xr.Descendants(xn + "Cube") _
                     Where ECB.Attribute("currency") IsNot Nothing _
                     AndAlso ECB.Attribute("rate") IsNot Nothing _
                     Select New ECBItem With {
                        .Currency = ECB.Attribute("currency").Value,
                        .DisplayName = GetCurrencyName(ECB.Attribute( _
                          "currency").Value),
                        .Rate = Double.Parse(ECB.Attribute("rate").Value, New _
                        CultureInfo("en-US"))}
 
         For Each Item As ECBItem In xECBs
            Me.Add(Item)
         Next
      Catch ex As Exception
         Throw ex
      End Try
   End Sub
 
   Private Function GetCurrencyName(ByVal isoCode As String) As String
      Dim cultures As CultureInfo() = CultureInfo.GetCultures( _
        CultureTypes.SpecificCultures)
 
      For Each ci As CultureInfo In cultures
         Dim ri As New RegionInfo(ci.LCID)
         If ri.ISOCurrencySymbol = isoCode Then
            Return ci.DisplayName
         End If
      Next
      Return String.Empty
   End Function
End Class

<Window
   xmlns="http://schemas.microsoft.com/winfx/2006/xaml/presentation"
   xmlns:x="http://schemas.microsoft.com/winfx/2006/xaml"
   xmlns:my="clr-namespace:WpfApplication1" 
   x:Class="MainWindow" Loaded="Window_Loaded_1"
   Title="MainWindow" Height="350" Width="525">
   <Window.DataContext>
      <my:clsECB x:Name="myECBs" />
   </Window.DataContext>
 
   <Grid>
      <DataGrid x:Name="dgExchanges" AutoGenerateColumns="True" _
        ItemsSource="{Binding}" />
   </Grid>
</Window>

Class MainWindow 
 
   Private Sub Window_Loaded_1(sender As Object, e As RoutedEventArgs)
      Dim ecb As clsECB = DirectCast(FindName("myECBs"), clsECB)
      ecb.LoadExchanges()
   End Sub
End Class

Gru?
---------------------------------------------------
Snoopy sagt - vb@rchiv find ich gut...
Schon gesehen? OSMMapViewer V2 Control