vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
TOP-Angebot: 17 bzw. 24 Entwickler-Vollversionen zum unschlagbaren Preis!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Variablen/Strings · Sonstiges   |   VB-Versionen: VB623.11.04
Pfadangabe auf bestimmte Anzahl Zeichen reduzieren

Dieser Tipp zeigt, wie sich eine lange Pfadangabe auf eine bestimmte Anzahl Zeichen reduzieren lässt, ohne dass diese einfach rechts abzuschneiden.

Autor:   Tobias SurmannBewertung:     [ Jetzt bewerten ]Views:  11.490 
www.tssev.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Manchmal muss man einen langen Pfad reduzieren, und zwar so, dass immer noch einfach erkannt werden kann, um welche Datei es sich handelt und wo genau sie liegt. Eine typische Anwendung ist die Liste der letzten geöffneten Dateien in einem Textverarbeitungsprogramm. Das Menü ist leider nicht unendlich groß und so muss die Pfadangabe möglichst geschickt reduziert werden. Im nachfolgenden Tipp wird dies durch das Einsetzen von drei Punkten erreicht. Die maximale Zeichenlänge kann selbst festgelegt werden.

Public Function CompressedFilePath(strPath As String, maxZeichen As Long) As String
  ' Deklarationen
  Dim strArray() As String
  Dim strDrive As String
  Dim strTemp As String
  Dim i As Long
  Dim j As Long
 
  ' strPath ist bereits kleiner (oder gleich) maxZeichen
  If Len(strPath) <= maxZeichen Then
    CompressedFilePath = strPath
    Exit Function
  End If
 
  ' Verzeichnisebenen in Array aufsplitten
  strArray = Split(strPath, "\")
 
  ' Laufwerksbuchstaben zwischenspeichern
  strDrive = Left$(strPath, 3)
 
  ' Reduzierungsstufen durchgehen
  For i = 0 To UBound(strArray)
    strTemp = ""
    For j = i To UBound(strArray)
      strTemp = strTemp & strArray(j) & IIf(j = UBound(strArray), "", "\")
    Next j
 
    ' prüft, ob aktuelle Reduzierung kleiner (oder gleich) geforderter Länge ist
    If Len(strTemp) + 7 <= maxZeichen Then
      ' Rückgabepfad zusammensetzen
      CompressedFilePath = strDrive & "...\" & strTemp
      Exit Function
    End If
  Next i
 
  ' an dieser Stelle ist klar, dass keine Reduzierung vorgenommen werden konnte
  ' deshalb wird der ursprüngliche Pfad zurückgegeben
  CompressedFilePath = strPath
End Function

Beispiele:

' txtPfad enthält den Text "C:\Dokumente und Einstellungen\Benutzer\Eigene Dateien\Zinsen.doc"
' und soll auf eine Länge von 50 Zeichen reduziert werden
txtPfad = CompressedFilePath(txtPfad, 50)

Im Textfeld txtPfad wird "C:\...\Benutzer\Eigene Dateien\Zinsen.doc" ausgegeben.

Im nächsten Beispiel befindet sich der Pfad schon in einer optimalen Form.

' txtPfad enthält den Text "C:\Texte\Notizen.txt"
' und soll auf eine Länge von 40 Zeichen reduziert werden
txtPfad = CompressedFilePath(txtPfad, 40)

Da die Pfadlänge bereits kleiner als 40 Zeichen ist, wird direkt der übergebene Pfad zurückgegeben.

Ein letztes Beispiel soll zeigen, dass eine Reduktion nicht immer möglich ist!

' txtPfad enthält den Text "C:\a\bc.txt"
' und soll auf eine Länge von 10 Zeichen reduziert werden
txtPfad = CompressedFilePath(txtPfad, 10)

Hier wird wiederum der übergebene Pfad zurückgegeben, da ein "Auspunkten" des Verzeichnisses a zu einer noch längeren Zeichenkette führt. Deshalb ist es in diesem Fall ratsam den Rückgabestring von CompressedFilePath() auf seine Länge zu untersuchen:

' txtPfad enthält den Text "C:\a\bc.txt"
' und soll auf eine Länge von 10 Zeichen reduziert werden
txtPfad = CompressedFilePath(txtPfad, 10)
If Len(txtPfad) > 10 Then
  MsgBox "Pfadreduktion nicht möglich!"
Else
  MsgBox "Es hat geklappt!"
End If

Dieser Tipp wurde bereits 11.490 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel