Label-Größe an Inhalt anpassen Diesmal zeigen wir, wie man die Höhe eines Label-Controls autom. an den Inhalt anpassen kann.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  14.835
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 6 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.8 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Immer dann, wenn man keine fest vorderinierten Texte in Label-Controls anzeigen muss, kann es bei der Darstellung zu Problemen kommen. Denn oftmals ist beim Entwurf des Formulars der Inhalt nicht bekannt, so dass man die Höhe des Controls nicht exakt festlegen kann.

Beispiel: Beim Laden eines Formulars soll im Label-Control ein variabler Text angezeigt werden. Dieser kann 2 Zeilen aber auch 5 Zeilen umfassen. Wie kann man nun die Größe (nur die Höhe; die Breite soll fix bleiben) des Labels verändern, so dass immer der komplette Inhalt angezeigt wird?

Die AutoSize-Eigenschaft des Label-Controls scheidet hier aus, da hier sowohl die Breite als auch die Höhe angepasst wird.

Wie schon so oft, hilft uns hier aber wieder das Windows-API aus der Klemme.
Fügen Sie hierzu nachfolgenden Code in den Codeteil der Form ein.

Option Explicit
 
' benötigte API's
Private Declare Function DrawText Lib "user32" _
  Alias "DrawTextA" ( _
  ByVal hdc As Long, _
  ByVal lpStr As String, _
  ByVal nCount As Long, _
  lpRect As RECT, _
  ByVal wFormat As Long) As Long
 
Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type
 
Const DT_CALCRECT = &H400
Const DT_WORDBREAK = &H10

Private Function CalcLabelHeight(ByVal sText As String, _
  ByVal nWidth As Long) As Long
 
  ' benötigte Höhe für die Anzeige von "sText" 
  ' berechnen, unter Berücksichtigung der fest 
  ' vorgegebenen Breite
 
  Dim nResult As Long
  Dim R As RECT
 
  ' Rechteck ermitteln
  R.Right = nWidth / Screen.TwipsPerPixelX
  nResult = DrawText(Me.hdc, sText, Len(sText), R, DT_CALCRECT Or DT_WORDBREAK)
 
  ' benötigte Höhe zurückgeben
  CalcLabelHeight = (nResult * Screen.TwipsPerPixelY)
End Function

Aufrufbeispiel:

Dim sText As String
 
sText = "Dies ist ein mehrzeiliger Text." & vbCrLf & _
  "Das Label sollte sich autom. in der Höhe anpassen."
 
Label1.Height = CalcLabelHeight(sText, Label1.Width)
Label1.Caption = sText