ReplacePlus auf Basis "regulärer Ausdrücke" Ersetzen ohne Berücksichtigung von Groß- und Kleinschreibung und Ersetzen von Wörtern
Autor:   Carsten Stuplich	Bewertung:     [ Jetzt bewerten ]	Views:  10.798
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 17 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.2 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Bei der Replace-Funktion von Visual Basic 6 können Sie nicht bestimmen, dass nur ganze Wörter anstatt Zeichenketten ersetzt werden.
Mit der nachfolgenden Funktion ReplacePlus ist dies ab sofort möglich!

Damit die Funktion möglichst schnell ist, wird nicht wie bei anderen Funktionen, die ich für diesen Zweck im Internet gefunden habe, eine Schleife durchlaufen, sondern auf Reguläre-Ausdrücke zurückgegriffen.

Da VB6 selbst keine Regulären-Ausdrück kennt, müssen Sie folgenden Verweis in das Projekt aufnehmen (Sie können auch eine neuere Version verwenden):

Microsoft VBScript Regular Expressions 5.0

Jetzt kopieren Sie noch folgende Funktion in ein Modul:

Public Function ReplacePlus(ByVal Text As String, _
  ByVal oldChar As String, _
  ByVal newChar As String, _
  Optional ByVal bIgnoreCase As Boolean = True, _
  Optional ByVal bReplaceOnlyWholeWords As Boolean = False) As String
 
  ' Mit dieser Replace-Funktion kann man u.a. auch festlegen, 
  ' dass nur ganze Worte ersetzt werden.
 
  ' Als Verweis müssen Sie "Microsoft VBScript Regular Expressions 5.0" oder höher 
  ' in das Projekt aufnehmen, damit Sie in VB6 mit "Regulären Ausdrücken" arbeiten 
  ' könnnen.
 
  ' Da VBScript nicht auf jedem Rechner installiert ist, sollten Sie ein Setup 
  ' für Ihr Programm erstellen
 
  If bReplaceOnlyWholeWords = True Then
    ' Replace mit Expression bei Wörtern
    With New RegExp
      .IgnoreCase = bIgnoreCase
      .Global = True
      .MultiLine = True
      .Pattern = "\b" & oldChar & "\b"
 
      ReplacePlus = .Replace(Text, newChar)
    End With
 
  Else
    ' Normales Replace
    If bIgnoreCase = True Then
      ReplacePlus = Replace(Text, oldChar, newChar, , , vbTextCompare)
    Else
      ReplacePlus = Replace(Text, oldChar, newChar, , , vbBinaryCompare)
    End If
  End If
End Function

Beispiel:

sText = "Ich weiß nicht, wo das Problem beim Replace von Wörtern liegen soll :-)"
 
' Ergebnis: ICH weiß nicht, wo das Problem beim Replace von Wörtern liegen soll :-)
MsgBox ReplacePlus(sText, "ich", "ICH", , True)

Hinweis:
Wenn Sie viele Wörter (z.B. innerhalb einer Schleife) ersetzen und nicht wissen, ob das Wort/Zeichen im Text enthalten ist, sollten Sie vor dem Aufruf von ReplacePlus prüfen, ob die Zeichenkette überhaupt im Text enthalten ist. Dies beschleunigt das ganze noch einmal, wenn die zu ersetzende Zeichenkette bzw. das Wort nicht im Text enthalten ist.

Im folgenden Beispiel werden alle Wörter eines Arrays ersetzt, um diese innerhalb eines RTF-Controls farblich hervorzuheben.
(Die entsprechende Prüfung ist fett markiert):

For i = LBound(aSQLKeywords) To UBound(aSQLKeywords)
  If InStr(1, stmpSQL, aSQLKeywords(i), vbTextCompare) > 0 Then
    stmpSQL = ReplacePlus(stmpSQL, aSQLKeywords(i), _
      "{\cf2 " & aSQLKeywords(i) & "}", True, True)
  End If
Next i