Neuzeichnen von Fensterinhalten sperren Dieser Tipp zeigt, wie Sie das automatische Neuzeichnen von Fensterinhalten bei Bedarf gezielt ausschalten und später wieder einschalten.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  16.474
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 9 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.6 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Kennen Sie das auch? Der Fensterinhalt flackert, während eine bestimmte Aktion bzw. eine Vielzahl von Aktionen ausgeführt wird? Wie Sie diesen unangenehmen und störenden Effekt ausschalten, zeigt Ihnen der nachfolgende Tipp.

' zunächst die benötigten API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Long) As Long
Private Declare Function GetClientRect Lib "user32" ( _
  ByVal hWnd As Long, _
  lpRect As cRECT) As Long
Private Declare Function RedrawWindow Lib "user32" ( _
  ByVal hWnd As Long, _
  lprcUpdate As cRECT, _
  ByVal hrgnUpdate As Long, _
  ByVal fuRedraw As Long) As Long
 
Private Const WM_SETREDRAW = &HB
Private Const RDW_INVALIDATE = &H1
Private Const RDW_ALLCHILDREN = &H80
Private Const RDW_UPDATENOW = &H100
Private Const RDW_ERASE = &H4
 
Private Type cRECT
  left As Long
  top As Long
  right As Long
  bottom As Long
End Type
 
Public Sub LockWindow(ByVal hWnd As Long, wLock As Boolean)
  Dim ClientRect As cRECT
 
  If wLock = True Then
    SendMessage hWnd, WM_SETREDRAW, False, 0&
  Else
    SendMessage hWnd, WM_SETREDRAW, True, 0&
    GetClientRect hWnd, ClientRect
    RedrawWindow hWnd, ClientRect, 0&, RDW_ERASE Or _
      RDW_INVALIDATE Or RDW_ALLCHILDREN Or RDW_UPDATENOW
  End If
End Sub

Beispiel

' Neuzeichnen deaktivieren
LockWindow Me.hWnd, True
 
' Aktionen ausführen
...
' Fensterinhalt neuzeichnen
LockWindow Me.hWnd, False