PopUp-Menü wird nicht angezeigt :-( In diesem Tipp verraten wir Ihnen, wie Sie Probleme mit PopUp-Menüs umgehen können, wenn diese unter bestimmten Umständen einfach nicht angezeigt werden.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  28.122
www.tools4vb.de	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 9 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 4.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Folgendes Szenario:

1. Auf einem Formular befindet sich ein ListView-Control
2. Bei Rechtsklick auf einen Eintrag soll ein PopUp-Menü angezeigt werden (via Me.PopUpMenu ...)
3. Im Click-Event des Menü-Eintrags wird eine zweite Form modal aufgerufen, die ebenfalls ein ListView oder TreeView-Control enthält
4. Auch im zweiten Formular soll per Rechtsklick auf einen Listeneintrag wieder ein PopUp-Menü aufgerufen werden können
5. Leider Fehlanzeige! Das PopUp-Menü wird nicht angezeigt!

Ursache:
Beim Aufruf des PopUp-Menüs im ersten Formular beansprucht das Menü alle Tastatur- und Mausereignisse für sich und zwar solange, bis das Click-Event des PopUp-Menüs vollständig abgearbeitet wurde. Dadurch dass die zweite Form aber modal geladen wird, bleibt die Ausführung des Codes in Form1 zunächst nach Aufruf der "Form2.Show vbModal"-Methode stehen.

Abhilfe schafft hier der Einsatz eines Timers.
Anstelle die zweite Form im Click-Event des PopUp-Menüs aufzurufen wird der Timer mit einer kurz eingestellten Intervallzeit gestartet. Die Click-Prozedur hat nun genügend Zeit den restlichen Code abzuarbeiten, ehe dann das Timer-Ereignis eintritt. Von hier aus wird dann die zweite Form aufgerufen und schon funktioniert's mit dem PopUp-Menü in der zweiten Form.

Beispiel:
Erstellen Sie ein neues Projekt:

1. Platzieren Sie auf die Form1 einen CommandButton (Command1) und ein Timer-Control (Timer1)
2. Öffnen Sie den VB-Menüeditor und erstellen einen neuen Menü-Eintrag "MyPopUp" mit Visible = False
3. Fügen Sie ein paar Untermenüs ein (mnuPopUp(0), mnuPopUp(1), etc.)
4. Fügen Sie dem Projekt eine neue Form hinzu (Form2)
5. Platzieren Sie auf die 2. Form ebenfalls wieder einen CommandButton (Command1)
6. Erstellen Sie für die zweite Form das gleiche PopUp-Menü wie für die erste Form

Code für die Form1
Fügen Sie nachfolgenden Code in den Codeteil der Form1:

Private Sub Command1_Click()
  ' Bei Klick auf den Button, PopUp-Menü öffnen
  Me.PopupMenu MyPopUp
End Sub

Private Sub mnuPopUp_Click(Index As Integer)
  ' Test: ohne Timer wird die zweite Form
  ' zwar korrekt angezeigt, jedoch wird dort dann kein 
  ' weiteres PopUp-Menü mehr angezeigt
  ' If Index = 0 Then
  '   Load Form2
  '   Form2.Show vbModal
  ' End If
  ' Exit Sub
 
  ' Form2 öffnen
  ' Umweg über Timer!
  Timer1.Tag = Index
  Timer1.Interval = 20
  Timer1.Enabled = True
End Sub

Private Sub Timer1_Timer()
  Dim Index As Integer
 
  ' Timer deaktivieren  
  Timer1.Enabled = False
 
  ' mnuPopUp_Click hier auswerten!
  Index = Val(Timer1.Tag)
 
  If Index = 0 Then
    ' Bei Auswahl des ersten Menü-Eintrags, Form2 anzeigen
    Load Form2
    Form2.Show vbModal
  End If
End Sub

Code für die Form2:
Fügen Sie nachfolgenden Code in den Codeteil der Form2 ein:

<code>Private Sub Command1_Click()
  ' Bei Klick auf den Button, PopUp-Menü öffnen
  Me.PopupMenu MyPopUp
End Sub