vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Zippen wie die Profis!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: System/Windows · Computer/Benutzer/Ländereinstellungen   |   VB-Versionen: VB5, VB618.09.06
Aktuelle Zeitzone im Klartext ermitteln

Dieser Tipp gibt die aktuell eingestelle Zeitzone des Computer im Klartext wieder

Autor:   Microsys KramerBewertung:     [ Jetzt bewerten ]Views:  14.921 
www.access-paradies.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Mit diesem Tipp wird die aktuell eingestellte Zeitzone des Systems zurückgegeben.

Fügen Sie nachfolgenden Code in ein Modul ein:

Option Explicit
 
' Benötigte API-Deklarationen 
Private Type SYSTEMTIME
  wYear         As Integer
  wMonth        As Integer
  wDayOfWeek    As Integer
  wDay          As Integer
  wHour         As Integer
  wMinute       As Integer
  wSecond       As Integer
  wMilliseconds As Integer
End Type
 
Private Type TIME_ZONE_INFORMATION
  ' Basis-Zeitverschiebung in Minuten
  Bias As Long   
  ' Name der Sommerzeit-Zeitzone
  StandardName(0 To ((32 * 2) - 1)) As Byte
  ' Beginn der Standardzeit
  StandardDate As SYSTEMTIME
  ' Zusätzliche Zeitverschiebung der Standardzeit
  StandardBias As Long
  ' Name der Sommerzeit-Zeitzone
  DaylightName(0 To ((32 * 2) - 1)) As Byte
  ' Beginn der Sommerzeit
  DaylightDate As SYSTEMTIME
  ' Zusätzliche Zeitverschiebung der Sommerzeit
  DaylightBias As Long
End Type
 
Private Declare Function GetTimeZoneInformation Lib "kernel32" ( _
  lpTimeZoneInformation As TIME_ZONE_INFORMATION) As Long
' // -----------------------------------------------------------------
 ' // Methode:   | Ermittelt die aktuell, eingestellte Zeitzone
 ' // -----------------------------------------------------------------
 ' // Parameter: | -
 ' // -----------------------------------------------------------------
 ' // Rückgabe:  | Klartext der Zeitzone
 ' // -----------------------------------------------------------------
Public Function GetCurrentTimeZone() As String
  On Error GoTo Err_GetCurrentTimeZone
 
  Dim tzi As TIME_ZONE_INFORMATION
  Dim tmp As String
 
  Select Case GetTimeZoneInformation(tzi)
    Case 0:  tmp = "Die aktuelle Zeitzone konnte nicht ermittelt werden"
    Case 1:  tmp = tzi.StandardName
    Case 2:  tmp = tzi.DaylightName
  End Select
 
  GetCurrentTimeZone = TrimNull(tmp)
 
Exit_GetCurrentTimeZone:
  Exit Function
 
Err_GetCurrentTimeZone:
  GetCurrentTimeZone = "Die aktuelle Zeitzone konnte nicht ermittelt werden"
  Resume Exit_GetCurrentTimeZone
End Function
' // ----------------------------------------------------------------
' // Hilfsfunktion
' // -----------------------------------------------------------------
Private Function TrimNull(sValue As String)
  Dim iPos    As Integer
 
  iPos = InStr(sValue, Chr$(0))
  If iPos Then
    TrimNull = Left$(sValue, iPos - 1)
  Else
    TrimNull = sValue
  End If
End Function

Dieser Tipp wurde bereits 14.921 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel