vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
sevAniGif - als kostenlose Vollversion auf unserer vb@rchiv CD Vol.5  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Verschiedenes / Sonstiges   |   VB-Versionen: VB2005, VB200814.07.08
Assembler Code ausführen

Maschinencode mit VB Bordmitteln ausführen

Autor:   Arne ElsterBewertung:     [ Jetzt bewerten ]Views:  16.572 
actorics.de/rm_codeSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Ab und an ist es nützlich, auf die unterste Programmebene zurückzugreifen, den Assembler. Zum Beispiel dann, wenn Algorithmen besonders performant laufen sollen oder näher an der Hardware programmiert werden muss.

Folgendes Beispiel zeigt, wie bereits assemblierter Code, der den Herstellernamen der CPU ausliest, mithilfe der Marshal Klasse ausgeführt werden kann:

Imports System.Runtime.InteropServices
 
Module Module1
  Private Declare Function VirtualAlloc Lib "kernel32" ( _
    ByVal addr As IntPtr, _
    ByVal size As Integer, _
    ByVal alloctype As Integer, _
    ByVal protect As Integer) As IntPtr
 
  Private Declare Function VirtualFree Lib "kernel32" ( _
    ByVal addr As IntPtr, _
    ByVal size As Integer, _
    ByVal freetype As Integer) As Integer
 
  Private Const MEM_COMMIT As Integer = &H1000
  Private Const MEM_DECOMMIT As Integer = &H4000
  Private Const PAGE_EXEC_RW As Integer = &H40
 
  ' Über dieses Delegate wird der Maschinencode aufgerufen.
  ' Das Attribut "Out" ist wichtig, damit VB weiß, dass
  ' ASMGetCPUName Daten in str schreiben wird
  Delegate Sub ASMGetCPUName(<Out()> ByVal str() As Char)
  Sub Main()
    ' ; Dieser ASM Code soll ausgeführt werden:
    '
    ' push ebx
    ' xor eax, eax
    ' cpuid
    ' mov eax, [esp+8]
    ' mov [eax+0], ebx
    ' mov [eax+4], edx
    ' mov [eax+8], ecx
    ' pop ebx
    ' ret 4
 
    ' obiges Assembler Listing in Maschinencode übersetzt (mit Nasm)
    ' und in 4 Byte Blöcke (Integer) aufgeteilt
    Dim code() As Integer = {264253779, 608471970, -1994880760, _
      1216939088, 79846152, 0}
 
    ' Buffer für CPU Hersteller Name
    Dim name() As Char = New String(" "c, 12).ToCharArray()
    ' ausführbaren Speicher beim System beantragen
    Dim mem As IntPtr = VirtualAlloc(Nothing, code.Length, _
      MEM_COMMIT, PAGE_EXEC_RW)
 
    If mem.ToInt32 = 0 Then
      MsgBox("Fehler bei Aufruf von VirtualAlloc!", MsgBoxStyle.Exclamation)
    Else
      ' Delegate für Unmanaged Code erzeugen
      Dim fnc As ASMGetCPUName = CType( _
        Marshal.GetDelegateForFunctionPointer(mem, _
        GetType(ASMGetCPUName)), ASMGetCPUName)
 
      ' Code in Speicher kopieren
      Marshal.Copy(code, 0, mem, code.Length)
      ' Maschinencode ausführen
      fnc(name)
      ' Speicher wieder freigeben
      VirtualFree(mem, code.Length, MEM_DECOMMIT)
 
      MsgBox("CPU Name: " & name)
    End If
  End Sub
End Module

Dieser Tipp wurde bereits 16.572 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel