vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
SEPA-Dateien erstellen inkl. IBAN-, BLZ-/Kontonummernprüfung  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Grafik und Font   |   VB-Versionen: VB2005, VB200810.10.08
Rechteck mit abgerundeten Ecken zeichnen

Mit dieser überladenen Funktionen lassen sich abgerundete Rechtecke mit oder ohne Füllfarbe (auch Farbverläufe) zeichnen.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  20.814 
www.tools4vb.deSystem:  Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Normale Rechtecke zu zeichnen sollte kein Problem sein. Wie sieht es aber bei Rechtecken mit abgerundeten Ecken aus? Eine entsprechende Methode dazu sucht in .NET hier vergeblich.

Mit Hilfe des GraphicsPath-Objekt lässt sich das aber schnell erledigen.

Nachfolgend eine überladene Funktionen für das Zeichnen von Rechtecken mit abgerundeten Ecken. Die Rundung selbst wird variable über den Parameter "radius" angegeben. Die Angabe erfolgt in Pixel. Soll das Rechteck mit einer bestimmten Farbe oder gar einem Farbverlauf gefüllt werden, einfach ein Brush-Objekt als zusätzlichen Parameter angeben.

Imports System.Drawing.Drawing2D
''' <summary>
''' Abgerundetes Rechteck ohne Füllung zeichnen
''' </summary>
''' <param name="g">Graphics-Obkjekt, auf das die Ausgabe erfolgen soll</param>
''' <param name="r">Rechteck-Struktur</param>
''' <param name="radius">Radius der abgerundeten Ecken</param>
''' <param name="borderColor">Rahmenfarbe des Rechtecks</param>
Public Sub DrawRoundedRectangle(ByVal g As Graphics, _
  ByVal r As Rectangle, _
  ByVal radius As Single, _
  ByVal borderColor As Color)
 
  ' GraphicsPath erstellen
  Dim path As GraphicsPath = RectanglePath(r, radius)
 
  ' Rechteck mit angerundeten Ecken zeichnen
  g.DrawPath(New Pen(borderColor), path)
 
  ' Ressourcen freigeben
  path.Dispose()
End Sub
''' <summary>
''' Abgerundetes Rechteck mit Füllung zeichnen
''' </summary>
''' <param name="g">Graphics-Obkjekt, auf das die Ausgabe erfolgen soll</param>
''' <param name="r">Rechteck-Struktur</param>
''' <param name="radius">Radius der abgerundeten Ecken</param>
''' <param name="borderColor">Rahmenfarbe des Rechtecks</param>
''' <param name="fillBrush">Brush-Objekt für die Füllung</param>
Public Sub DrawRoundedRectangle(ByVal g As Graphics, _
  ByVal r As Rectangle, _
  ByVal radius As Single, _
  ByVal borderColor As Color, _
  ByVal fillBrush As Brush)
 
  ' GraphicsPath erstellen
  Dim path As GraphicsPath = RectanglePath(r, radius)
 
  ' Füllung zeichnen
  g.FillPath(fillBrush, path)
 
  ' Rechteck mit angerundeten Ecken zeichnen
  g.DrawPath(New Pen(borderColor), path)
 
  ' Ressourcen freigeben
  path.Dispose()
End Sub
''' <summary>
''' Hilfsfunktion: Erstellt einen GraphicsPath aus der
''' Größe des Rechtecks und dem angegeben Radius
''' </summary>
Private Function RectanglePath(ByVal r As RectangleF, _
  ByVal radius As Single) As GraphicsPath
 
  ' Neues GraphicsPath-Objekt erstellen
  Dim path As New GraphicsPath
  Dim d As Single = 2 * radius
 
  ' Zusammensetzen des GraphicsPath 
  With path
    If radius < 1 Then
      ' keine abgerundeten Ecken
      .AddRectangle(r)
    Else
      ' Linien und Bögen erstellen
      .AddLine(r.X + radius, r.Y, r.X + r.Width - d, r.Y)
      .AddArc(r.X + r.Width - d, r.Y, d, d, 270, 90)
      .AddLine(r.X + r.Width, r.Y + radius, r.X + r.Width, r.Y + r.Height - d)
      .AddArc(r.X + r.Width - d, r.Y + r.Height - d, d, d, 0, 90)
      .AddLine(r.X + r.Width - d, r.Y + r.Height, r.X + radius, r.Y + r.Height)
      .AddArc(r.X, r.Y + r.Height - d, d, d, 90, 90)
      .AddLine(r.X, r.Y + r.Height - d, r.X, r.Y + radius)
      .AddArc(r.X, r.Y, d, d, 180, 90)
    End If
    .CloseFigure()
  End With
 
  Return (path)
End Function

Beispiel für den Aufruf:
Platzieren Sie auf die Form eine PictureBox, in der das Rechteck mit den abgerundeten Ecken angezeigt werden soll. Die Größe des Rechtecks entspricht der Größe des PictureBox-Controls.

Private Sub PictureBox1_Paint(ByVal sender As Object, _
  ByVal e As System.Windows.Forms.PaintEventArgs) Handles PictureBox1.Paint
 
  ' Rechteck -Größe
  Dim r As Rectangle
  With PictureBox1.ClientRectangle
    r = New Rectangle(0, 0, .Width - 1, .Height - 1)
  End With
 
  ' Rundung in Pixel
  Dim radius As Single = 15
 
  ' abgerundetes Rechteck mit Farbverlauf zeichnen
  DrawRoundedRectangle(e.Graphics, r, radius, Color.Black, _
    New LinearGradientBrush(r, Color.AliceBlue, Color.RoyalBlue, _
    LinearGradientMode.Vertical))
End Sub

Dieser Tipp wurde bereits 20.814 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Aktuelle Diskussion anzeigen (1 Beitrag)

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel