vb@rchiv · Tipps & Tricks · Fremdanwendungen beenden

Rubrik: System/Windows · Prozesse/Tasks | VB-Versionen: VB4, VB5, VB6

10.05.01

Fremdanwendungen beenden Dieser Tipp zeigt, wie man beliebige gestartete Fremdanwendungen aus VB heraus beenden kann.
Autor: Heinz Prelle	Bewertung:	Views: 20.974
www.visual-basic5.de	System: Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Der nachfolgende Tipp zeigt, wie man beliebige gestartete Fremdanwendungen aus der eigenen Anwendung heraus beenden kann. Hierzu wird mit Hilfe der FindWindow-API das Fensterhandle der zu schließenden Anwendung ermittelt und dann über die Funktion SendMessage die Windows-Nachricht zum Schließen des Fensters "verschickt".

' zunächst die benötigten API-Deklarationen
Private Declare Function FindWindow Lib "user32" _
  Alias "FindWindowA" ( _
  ByVal sClassName As String, _
  ByVal lpWindowName As String) As Long
 
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  lParam As Any) As Long
 
Const WM_SYSCOMMAND = &H112
Const SC_CLOSE = &HF060
Const LNULL = 0&

Um das Fensterhandle mit FindWindow zu erhalten, muss der Klassenname, sowie der Windows-Name (Text der Titelzeile) angegeben werden.

Public Function CloseWindow(ByVal sClassName As String, _
  ByVal sCaption As String) As Boolean
 
  Dim lHandle As Long
  Dim lRet As Long
 
  lHandle = FindWindow(sClassName, sCaption)
  If lHandle <> 0 Then
    lRet = SendMessage(lHandle, WM_SYSCOMMAND, _
      SC_CLOSE, LNULL)
  End If
 
  CloseWindow = (lHandle <> 0)
End Function

Beispiel
Im nachfolgenden Beispiel wird der Windows-Taschenrechner beendet, sofern dieser gestartet ist.

If Not CloseWindow("SciCalc", "Rechner") Then
  MsgBox "Taschenrechner konnte nicht beendet werden." & _
    vbCrLf & "Evtl. wurde dieser nicht gestartet", _
    vbInformation, "Hinweis"
End If