Beliebiges CD-Laufwerk öffnen und schliessen Dieser Tipp zeigt, wie sich die CD-Schublade eines beliebiges CD-Laufwerk öffnen und schliessen lässt.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  36.971
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 62 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

In einem früheren Tipp haben wir Ihnen gezeigt, wie man die CD-Schublade des "Standard" CD-Laufwerks per Programmcode öffnen und schliessen kann. Nun haben Sie aber noch ein zweites CD-Laufwerk bzw. einen CD-Brenner eingebaut. Der nachfolgende Tipp zeigt nun, wie sich gezielt eines dieser beiden CD-Laufwerke öffnen bzw. schliessen lässt. Übergeben Sie dem Prozeduraufruf einfach den entsprechenden Laufwerksbuchstaben. Innerhalb der Prozedur wird "sicherheitshalber" nochmals geprüft, ob es sich bei dem angegebenen Laufwerk auch tatsächlich um ein CD-Laufwerk handelt.

Sie sehen also, der Tipp bietet sogar noch etwas mehr...

' zunächst die benötigten API-Deklarationen
Option Explicit
Private Declare Function mciSendString Lib "winmm.dll" _
  Alias "mciSendStringA" ( _
  ByVal lpstrCommand As String, _
  ByVal lpstrReturnString As String, _
  ByVal uReturnLength As Long, _
  ByVal hwndCallback As Long) As Long
 
Private Declare Function GetDriveType Lib "kernel32" _
  Alias "GetDriveTypeA" ( _
  ByVal nDrive As String) As Long
 
Private Const DRIVE_CDROM = 5

CD-Laufwerks-Schublade öffnen
Geben Sie beim Aufruf der Prozedur den Laufwerksbuchstaben des zu öffnenen CD-Laufwerks an. Erfolgt keine Angabe des Laufwerksbuchstabens, so wird das "Standard" CD-Laufwerk geöffnet.

' beliebiges CD-ROM Laufwerk öffnen
Public Sub x_CDOpen(Optional CDDrive As String = "")
 
  Dim Buffer As String * 255
  Dim DriveType As Long
 
  ' Wenn Laufwerksbuchstabe angegeben, dann prüfen
  ' ob es sich um ein CD-Laufwerk handelt
  If CDDrive <> "" Then
    DriveType = GetDriveType(CDDrive)
    If DriveType <> DRIVE_CDROM Then
      MsgBox "Laufwerk " & CDDrive & " ist kein " & _
        "CD-Laufwerk", 16
      Exit Sub
    End If
 
    ' CD-Laufwrek öffnen
    mciSendString "Open " & CDDrive & _
      " Type cdaudio Alias cd", Buffer, 255, 0
    mciSendString "set cd door open", 0&, 0, 0
    mciSendString "close cd", 0&, 0, 0
 
  ' keine Laufwerksangabe -> Standard CDROM-Laufwerk
  ' öffnen
  Else
    mciSendString "set cdaudio door open", 0&, 0, 0
  End If
End Sub

CD-Laufwerks-Schublade schliessen
Geben Sie beim Aufruf der Prozedur den Laufwerksbuchstaben des zu schliessendeb CD-Laufwerks an. Erfolgt keine Angabe des Laufwerksbuchstabens, so wird das "Standard" CD-Laufwerk geschlossen.

' beliebiges CD-ROM Laufwerk schliessen
Public Sub x_CDClose(Optional CDDrive As String = "")
 
  Dim Buffer As String * 255
  Dim DriveType As Long
 
  ' Wenn Laufwerksbuchstabe angegeben, dann prüfen
  ' ob es sich um ein CD-Laufwerk handelt
  If CDDrive <> "" Then
    DriveType = GetDriveType(CDDrive)
    If DriveType <> DRIVE_CDROM Then
      MsgBox "Laufwerk " & CDDrive & " ist kein " & _
        "CD-Laufwerk", 16
      Exit Sub
    End If
 
    ' CD-Laufwrek schliessen
    mciSendString "Open " & CDDrive & _
      " Type cdaudio Alias cd", Buffer, 255, 0
    mciSendString "set cd door closed", 0&, 0, 0
    mciSendString "close cd", 0&, 0, 0
 
  ' keine Laufwerksangabe -> Standard CDROM-Laufwerk
  ' schliessen
  Else
    mciSendString "set cdaudio door closed", 0&, 0, 0
  End If
End Sub

Beispiel
Um das Beispiel auszuprobieren, erstellen Sie ein neues Prohekt und fügen den gesamten oben angegebenen Quellcode in die Form1 ein. Platzieren Sie auf der Form zwei CommandButtons - einen zum Öffnen des CD-Laufwerks, und einen zum Schliessen. Dann platzieren Sie noch ein Eingabefeld (Text1) aus die Form. Hier können Sie den Laufwerksbuchstaben eingeben.

' CD-Laufwerk öffnen
Private Sub Command1_Click()
  x_CDOpen Text1.Text
End Sub
 
' CD-Laufwerk schliessen
Private Sub Command2_Click()
  x_CDClose Text1.Text
End Sub

Anmerkung:
Bei Angabe des Laufwerksbuchstaben muss auch der Doppelpunkt angegeben werden, also z.B. H: oder I: