vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Dateisystem · Dateien allgemein   |   VB-Versionen: VB4, VB5, VB617.06.01
Dokumentverknüpfung erstellen (registrieren)

Dieser Tipp zeigt, wie Sie einen Dateityp mit einer bestimmten Anwendung verknüpfen.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  23.560 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Sie kennen das: Im Explorer wird eine .DOC-Datei (WinWord) angezeigt und per Doppelklick öffnet sich dann die verknüpfte Anwendung, also z.B. WinWord. Nun habe Sie eine Anwendung erstellt, z.B. einen Texteditor. Also wäre es doch schön, wenn anstelle des "Windows-Editors" bei einem Doppelklick im Explorer Ihre Anwendung geöffnet wird.

Um dies zu realisieren, muss man sich wieder einmal der Windows-API-Funktionen bedienen und den Dokumenttyp in der Windows-Registrierdatenbank registrieren (mit der gewünschten Anwendung verknüpfen).

Am besten ist es, wenn Sie den gesamten nachfolgenden Code in ein separates Modul "packen".

Option Explicit
 
' zunächst alle benötigten API-Deklarationen
Private Const HKEY_LOCAL_MACHINE = &H80000002
 
Private Const KEY_ALL_ACCESS = &H3F
Private Const KEY_SET_VALUE = &H2
Private Const KEY_CREATE_SUB_KEY = &H4
 
Private Const REG_PRIMARY_KEY = "Software\Classes\"
Private Const REG_SHELL_KEY = "Shell\"
Private Const REG_SHELL_OPEN_KEY = "Open\"
Private Const REG_SHELL_OPEN_COMMAND_KEY = "Command"
 
Private Const REG_SZ = 1
Private Const REG_OPTION_NON_VOLATILE = 0
 
Private Const ERROR_SUCCESS = 0&
 
Private Type SECURITY_ATTRIBUTES
  nLength As Long
  lpSecurityDescriptor As Long
  bInheritHandle As Boolean
End Type
 
Private Declare Function RegCloseKey Lib "advapi32.dll" ( _
  ByVal hKey As Long) As Long
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" _
  Alias "RegOpenKeyExA" ( _
  ByVal hKey As Long, _
  ByVal lpSubKey As String, _
  ByVal ulOptions As Long, _
  ByVal samDesired As Long, _
  phkResult As Long) As Long
Private Declare Function RegCreateKeyEx Lib "advapi32.dll" _
  Alias "RegCreateKeyExA" ( _
  ByVal hKey As Long, _
  ByVal lpSubKey As String, _
  ByVal Reserved As Long, _
  ByVal lpClass As String, _
  ByVal dwOptions As Long, _
  ByVal samDesired As Long, _
  lpSecurityAttributes As SECURITY_ATTRIBUTES, _
  phkResult As Long, _
  lpdwDisposition As Long) As Long
Private Declare Function RegSetValue Lib "advapi32.dll" _
  Alias "RegSetValueA" ( _
  ByVal hKey As Long, _
  ByVal lpSubKey As Any, _
  ByVal dwType As Long, _
  ByVal lpData As String, _
  ByVal cbData As Long) As Long
 
Private Function OpenKey(lhKey As Long, SubKey As String, _
  ulOptions As Long) As Long
 
  Dim lhKeyOpen As Long
  Dim lResult As Long
 
  lhKeyOpen = 0
  lResult = RegOpenKeyEx(lhKey, SubKey, 0, ulOptions, _
    lhKeyOpen)
  If lResult <> ERROR_SUCCESS Then
    OpenKey = 0
  Else
    OpenKey = lhKeyOpen
  End If
End Function
 
Private Function CreateKey(lhKey As Long, SubKey As _
  String, NewSubKey As String) As Boolean
 
  Dim lhKeyOpen As Long
  Dim lhKeyNew As Long
  Dim lDisposition As Long
  Dim lResult As Long
  Dim Security As SECURITY_ATTRIBUTES
 
  lhKeyOpen = OpenKey(lhKey, SubKey, _
    KEY_CREATE_SUB_KEY)
  lResult = RegCreateKeyEx(lhKeyOpen, NewSubKey, 0, "", _
    REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, Security, _
    lhKeyNew, lDisposition)
  If lResult = ERROR_SUCCESS Then
    CreateKey = True
    RegCloseKey (lhKeyNew)
  Else
    CreateKey = False
  End If
  RegCloseKey (lhKeyOpen)
End Function
 
Private Function SetValue(lhKey As Long, SubKey As _
  String, sValue As String) As Boolean
 
  Dim lhKeyOpen As Long
  Dim lResult As Long
  Dim lTyp As Long
  Dim lByte As Long
 
  lByte = Len(sValue)
  lTyp = REG_SZ
  lhKeyOpen = OpenKey(lhKey, SubKey, KEY_SET_VALUE)
  lResult = RegSetValue(lhKey, SubKey, lTyp, sValue, _
    lByte)
  If lResult <> ERROR_SUCCESS Then
    SetValue = False
  Else
    SetValue = True
    RegCloseKey (lhKeyOpen)
  End If
End Function
 
' Datei-Verknüpfung in der Registry speichern
' Datei-Verknüpfung in der Registry speichern 
' sFileExt = Dateiendung (z.B. .txt) 
' sFileDescr = Beschreibung (z.B. Textdokument) 
' sAppID = Programm-Kennung (z.B. Mein Texteditor) 
' sOpenCmd = vollständiger Dateiname der Anwendung
' inkl. Parameter %1 
' (z.B. App.Path & "\" & App.EXEName & ".exe %1"
Public Function RegisterFile(sFileExt As String, _
  sFileDescr As String, sAppID As String, _
  sOpenCmd As String) As Boolean
 
  Dim hKey As Long
  Dim bSuccess As Boolean
 
  bSuccess = False
  hKey = HKEY_LOCAL_MACHINE
 
  ' File-Extension
  If CreateKey(hKey, REG_PRIMARY_KEY, sFileExt) Then
    If SetValue(hKey, REG_PRIMARY_KEY & sFileExt, _
      sAppID) Then
      ' AppID
      If CreateKey(hKey, REG_PRIMARY_KEY, sAppID) Then
        ' AppDescription
        If SetValue(hKey, REG_PRIMARY_KEY & sAppID, _
          sFileDescr) Then
          ' OpenCommand
          If CreateKey(hKey, REG_PRIMARY_KEY & sAppID, _
            REG_SHELL_KEY & REG_SHELL_OPEN_KEY & _
            REG_SHELL_OPEN_COMMAND_KEY) Then
            bSuccess = SetValue(hKey, REG_PRIMARY_KEY & _
              sAppID & "\" & REG_SHELL_KEY & _
              REG_SHELL_OPEN_KEY & _
              REG_SHELL_OPEN_COMMAND_KEY, sOpenCmd)
          End If
        End If
      End If
    End If
  End If
 
  RegisterFile = bSuccess
End Function

Beispiel

' .txt-Dateien registrieren
RegisterFile ".txt", "Textdokument", "MeinTexteditor", _
  App.Path & "\" & App.EXEName & ".exe %1"

Beim Doppelklicken auf eine Datei mit der Endung .txt wird nun Ihre Anwendung gestartet und das Dokument (der Dateinamen) als Paramater übergeben. Den Dateinamen ermitteln Sie dann über den Command$-Befehl.
 

Dieser Tipp wurde bereits 23.560 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel