Textdateien schnell auslesen Dieses Beispiel zeigt, wie sich eine Textdatei in einem Rutsch auslesen und anzeigen lässt.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  66.806
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 77 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.3 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Eine sehr häufig gestellte Frage ist, wie man den gesamten Inhalt einer Textdatei auslesen kann, um diesen dann z.B. in einer MultiLine-Textbox anzuzeigen. Sicher sagen Sie jetzt: Na das ist doch ganz einfach, das geht so...

Dim sLine As String
 
Open "IrgendEineDatei.txt" For Input As #1
While Not Eof(1)
  Line Input #1, sLine
  Text1.Text = Text1.Text & sLine & vbCrLf
Wend
Close #1

...und da haben Sie auch sicherlich Recht!

Es gibt aber eine viel schnellere Methode, den gesamten Inhalt auszulesen. Hierzu wird die Datei nicht sequentiell zum Lesen geöffnet, sondern binär (also For Binary). Über die Lof()-Funktion wird die Gesamtgröße der Datei ermittelt, um dann eine Variable entsprechend mit Leerzeichen zu füllen. Ist dies geschehen, wird der gesamte Datei-Inhalt mit Get... in diese Variable gelesen - und das war's schon. Es wird also keine While...Wend-Schleife benötigt!

Nachfolgend eine Funktion, welche auf die eben geschilderte Art den gesamten Inhalt einer beliebigen Datei ausliest und diesen dann als String (Text) zurückgibt.

' Beliebige Datei auslesen und
' Inhalt als String zurückgeben
Public Function ReadFile(ByVal sFilename As String) _
  As String
  Dim F As Integer
  Dim sInhalt As String
 
  ' Prüfen, ob Datei existiert
  If Dir$(sFilename, vbNormal) <> "" Then
    ' Datei im Binärmodus öffnen
    F = FreeFile: Open sFilename For Binary As #F
 
    ' Größe ermitteln und Variable entsprechend
    ' mit Leerzeichen füllen
    sInhalt = Space$(Lof(F))
 
    ' Gesamten Inhalt in einem "Rutsch" einlesen
    Get #F, , sInhalt
 
    ' Datei schliessen
    Close #F
  End If
 
  ReadFile = sInhalt
End Function

Anwendungsbeispiel
Erstellen Sie ein neues Formular und fügen eine Textbox ein, deren MultiLine-Eigenschaft Sie auf True setzen. Zusätzlich wird noch ein CommandButton namens cmdOpen benötigt. Plazieren Sie dann noch eine Instanz des CommonDialog-Steuerelements auf die Form. Dieses verwenden wir zur Dateiauswahl.

Klickt der Anwender nun auf den CommandButton, so erscheint der Windows Dateiauswahl-Dialog. Nach dem Auswählen und Bestätigen der Datei wird deren gesamter Inhalt dann in der TextBox angezeigt.

Private Sub cmdOpen_Click()
  ' Dateiauswahl
  On Local Error Resume Next
  With CommonDialog1
    .CancelError = True
    .Filter = "Textdatei (*.txt)|*.txt|" & _
      "alle Dateien (*.*)|*.*"
    .ShowOpen
 
    ' wenn nicht auf Abbrechen geklickt wurde
    If Err = 0 Then
      ' Datei-Inhalt einlesen und anzeigen
      Text1.Text = ReadFile(.Filename)
    End If
  End With
End Sub