vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Brandneu! sevEingabe v3.0 - Das Eingabecontrol der Superlative!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Variablen/Strings · Sonstiges   |   VB-Versionen: VB4, VB5, VB625.09.01
Wort-Häufigkeit in einem Textabsatz zählen

Ein Beispiel, das demonstriert, wie sich die Häufigkeit eines bestimmtes Wortes in einem Textabsatz zählen lässt.

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  17.059 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Das nachfolgende Beispiel zeigt, wie sich die Häufigkeit eines Wortvorkommens innerhalb eines Textabschnittes ermitteln lässt. Optional lassen sich noch folgende Einstellungen festlegen:

  • Nur ganzes Wort suchen (Nein = Standard)
  • Groß-/Kleinschreibung ignorieren (Ja = Standard)

Public Function WordCount(ByVal sText As String, _
  ByVal sWord As String, _
  Optional ByVal bWholeWord As Boolean = False, _
  Optional ByVal bIgnoreCase As Boolean = True) As Long
 
  ' Durchsucht einen Textabschnitt nach einem
  ' bestimmten Word und gibt die Anzahl der 
  ' gefundenen Stellen zurück
 
  Dim lPos As Long
  Dim sCharLeft As String
  Dim sCharRight As String
  Dim Satzzeichen As String
  Dim nCount As Long
 
  Satzzeichen = ",.;:!? " + Chr$(13) + Chr$(10)
 
  ' Gross/Kleinschreibung ignorieren?
  If bIgnoreCase Then
    ' Wenn ja, zum Vergleich alles in 
    ' Kleinbuchstaben umwandeln
    sText = LCase$(sText)
    sWord = LCase$(sWord)
  End If
 
  ' Suche beginnen
  Do
    lPos = InStr(lPos + 1, sText, sWord)
    If lPos > 0 Then
      ' Wort gefunden
      If bWholeWord Then
        ' Wenn Suche nach ganzem Wort, Zeichen
        ' links und rechts von der "Funstelle" prüfen
        sCharLeft = "": sCharRight = ""
        If lPos > 0 Then sCharLeft = Mid$(sText, lPos - 1, 1)
        sCharRight = Mid$(sText, lPos + Len(sWord), 1)
 
        If (InStr(Satzzeichen, sCharLeft) > 0 Or _
          sCharleft = "") And _
          (InStr(Satzzeichen, sCharRight) > 0 Or _
          sCharRight = "") Then
 
          nCount = nCount + 1
        End If
      Else
        ' Ansonsten Zähler erhöhen
        nCount = nCount + 1
      End If
    End If
 
    ' Solange weitersuchen, bis keine (weitere)
    ' Funstelle mehr existiert
  Loop Until lPos = 0
 
  WordCount = nCount
End Function

Ein paar Erläuterungen:
Soll die Groß-/Kleinschreibung unbeachtet bleiben, so werden zunächst der Textabschnitt selbst, als auch das gesuchte Wort in Kleinbuchstaben umgewandelt. Dies erfolgt bereits vor der eigentlichen Suche, so dass man sich die sonst wiederholende "Umwandlung" innerhalb der Suchroutine spart.

Die Suche selbst erfolgt mit Hilfe der InStr-Funktion, wobei im ersten Parameter die Position angegeben wird, ab der die Suche erfolgen soll. Wird ein Eintrag gefunden, so enthält dieser Paramater beim nächsten Durchlauf automatisch die Position der Fundstelle + 1, so dass die "Weitersuche" dann ab dieser Position erfolgt.

Wurde das gesuchte Wort im Textabschnitt gefunden, so muss - falls die Suche "nur nach ganzem Wort" eingeschaltet ist - sowohl das Zeichen links von der Funstelle, als auch das Zeichen rechts von der Funstelle geprüft werden, ob es sich bei den jeweiligen Zeichen um Satzzeichen handelt (die Satzzeichen selbst sind in der gleichnamigen Variable Satzzeichen gespeichert). Nur wenn die Zeichen in "Satzzeichen" enthalten sind oder es gar kein Zeichen links oder rechts von der Funstelle gibt, darf der Zähler um eins erhöht werden!

Die Suchschleife selbst (Do...Loop) wird solange durchlaufen, bis die InStr-Funktion den Wert 0 zurückgibt. Dann nämlich konnte das gesuchte Wort nicht gefunden werden.
 

Dieser Tipp wurde bereits 17.059 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Aktuelle Diskussion anzeigen (2 Beiträge)

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel