Fenster-Hintergrund mit Farbverlauf (optimiert) Ein einfaches Beispiel, das zeigt, wie man einen Hintergrund-Farbverlauf in einem Fenster erstellt.
Autor:   Baar Lun	Bewertung:     [ Jetzt bewerten ]	Views:  14.074
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 18 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.1 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Die nachfolgende Routine erzeugt einen Hintergrund-Farbverlauf für ein bestimmtes Formular.

Diesen Tipp gab es bereits in ähnlicher Form in unserem Archiv. Jedoch traten Probleme auf, wenn das Fenster vergrößertwurde, und zwar wurden dann die Farben nicht mehr originalgetreu angezeigt.

Hier nun die optimierte Fassung:

' Farbverlauf
Public Sub Farbverlauf(Objekt As Object, _
  ByVal VonFarbe As Long, ByVal ZuFarbe As Long)
 
  Dim bvf As Long, gvf As Long, rvf As Long
  Dim bzf As Long, gzf As Long, rzf As Long
  Dim Rs As Single, Gs As Single, Bs As Single
  Dim yp As Long
  Dim TempScaleMode As Byte
  Dim TempAutoRedraw As Boolean
 
  ' RGB-Farbanteile "VonFarbe"
  bvf = Int(VonFarbe / (256 ^ 2))
  VonFarbe = VonFarbe - (bvf * (256 ^ 2))
  gvf = Int(VonFarbe / (256 ^ 1))
  VonFarbe = VonFarbe - (gvf * (256 ^ 1))
  rvf = Int(VonFarbe / (256 ^ 0))
 
  ' RGB-Farbanteile "ZuFarbe"
  bzf = Int(ZuFarbe / (256 ^ 2))
  ZuFarbe = ZuFarbe - (bzf * (256 ^ 2))
  gzf = Int(ZuFarbe / (256 ^ 1))
  ZuFarbe = ZuFarbe - (gzf * (256 ^ 1))
  rzf = Int(ZuFarbe / (256 ^ 0))
  With Objekt
    ' Die alten Werte temporär speichern
    TempScaleMode = .ScaleMode
    TempAutoRedraw = .AutoRedraw
    .ScaleMode = 3      'Pixel
    .AutoRedraw = True
    Rs = (rzf - rvf) / .ScaleHeight
    Gs = (gzf - gvf) / .ScaleHeight
    Bs = (bzf - bvf) / .ScaleHeight
    For yp = 0 To .ScaleHeight
      Objekt.Line (0, yp)-(.ScaleWidth, yp), _
       RGB(rvf + Rs * yp, gvf + Gs * yp, bvf + Bs * yp)
    Next
    ' Die alten Werte wiederherstellen
    .ScaleMode = TempScaleMode
    .AutoRedraw = TempAutoRedraw
  End With
End Sub

Beispiel:
Um einen Blau-Weissen Farbverlauf zu erzeugen, rufen Sie die Prozedur wie folgt auf:

Private Sub Form_Load()
  ' Farbverlauf von blau nach weiss
  Farbverlauf Me, &H800000, vbWhite
End Sub

Anmerkung: Der Farbverlauf lässt sich ohne weiteres auch auf Picture-Objekte anwenden.