vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
NEU! sevCoolbar 3.0 - Professionelle Toolbars im modernen Design!  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2019
 
zurück
Rubrik: Controls · StatusBar/ProgressBar   |   VB-Versionen: VB4, VB5, VB613.11.01
ProgressBar - Marke Eigenbau

Eine ProgressBar mit freier Farbwahl und optionaler Prozentanzeige - alles in reinem VB - ohne zusätzliche Controls!

Autor:   Dieter OtterBewertung:     [ Jetzt bewerten ]Views:  23.758 
www.tools4vb.deSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Jeder kennt sie - die Standard ProgressBar. Sie ist Bestandteil der Windows Common Controls und reicht in aller Regel auch aus. Ein Nachteil der Standard ProgressBar ist allerdings, dass sich die Farben nicht universell einstellen lassen - und auch Prozentanzeige fehlt.

Was liegt also näher, sich eine eigene ProgressBar zu "bauen". Das ganze lässt sich mit reinen VB-Boardmitteln ohne Verwendung zusätzlicher Steuerelemente realisieren.

Alles, was man für eine ProgressBar benötigt, ist ein Picture-Control - nicht mehr und nicht weniger.

Um den nachfolgenden Code zu testen, erstellen Sie ein neues Projekt und fügen eine PictureBox auf die Form - in der Größe, wie auch später die Fortschrittsanzeige dargestellt werden soll.

Und hier der Code

' Fortschritsanzeige
Private Sub ShowProgress(picProgress As PictureBox, _
  ByVal Value As Long, _
  ByVal Min As Long, _
  ByVal Max As Long, _
  Optional ByVal bShowProzent As Boolean = True)
 
  Dim pWidth As Long
  Dim intProz As Integer
  Dim strProz As String
 
  ' Farben
  Const progBackColor = &HC00000
  Const progForeColor = vbBlack
  Const progForeColorHighlight = vbWhite
 
  ' Plausibilitätsprüfungen
  If Value < Min Then Value = Min
  If Value > Max Then Value = Max
 
  ' Prozentwert ausrechnen
  If Max > 0 Then
    intProz = Int(Value / Max * 100 + 0.5)
  Else
    intProz = 100
  End If
 
  With picProgress
    ' Prüfen, ob AutoReadraw=True
    If .AutoRedraw = False Then .AutoRedraw = True
 
    ' Inhalt löschen
    picProgress.Cls
 
    If Value > 0 Then
 
      ' Balkenbreite
      pWidth = .ScaleWidth / 100 * intProz
 
      ' Balken anzeigen
      picProgress.Line (0, 0)-(pWidth, .ScaleHeight), _
        progBackColor, BF
 
      ' Prozentanzeige
      If bShowProzent Then
        strProz = CStr(intProz) & " %"
        .CurrentX = (.ScaleWidth - .TextWidth(strProz)) / 2
        .CurrentY = (.ScaleHeight - .TextHeight(strProz)) / 2
 
        ' Vordergrundfarbe
        If pWidth >= .CurrentX Then
          .ForeColor = progForeColorHighlight
        Else
          .ForeColor = progForeColor
        End If
 
        picProgress.Print strProz
      End If
    End If
  End With
End Sub

Um nun die Fortschrittsanzeige zu testen, fügen Sie der Form noch einen CommandButton (Command1) hinzu. Und dann noch den nachfolgenden Code:

Option Explicit
 
Private Declare Sub Sleep Lib "kernel32" ( _
  ByVal dwMilliseconds As Long)
 
' Fortschrittsanzeige testen
Private Sub Command1_Click()
  Dim I As Long
 
  For I = 1 To 100
    ShowProgress picProgress, I, 1, 100
    Sleep 150
    DoEvents
  Next I
End Sub

Starten Sie das Projekt und überzeugen Sie sich von Ihrer persönlichen ProgressBar. Die Farben lassen sich über die entsprechenden Konstanten progBackColor, progForeColor und progForeColorHighlight festlegen.
 

Dieser Tipp wurde bereits 23.758 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2019 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel