Datei-Download via API-Funktion Mit dem Aufruf einer einzigen API-Funktion lassen sich Dateien oder Bilder aus dem Internet downloaden.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  54.650
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 105 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.0 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Unser heutiger Tipp stellt eine eher unbekannte API-Funktion vor, mit der sich Dateien aus dem Internet downloaden und lokal auf die Festplatte speichern lassen.

Es handelt sich hierbei um die URLDownloadToFile-Funktion, welche Bestandteil der urlmon.dll ist. Diese DLL finden Sie in Ihrem Windows-/System-Verzeichnis (bzw. SYSTEM32 unter NT/2000/XP).

Deklaration
Fügen Sie folgende Deklaration in den Allgemein-Teil Ihrer Form ein:

' Benötigt wird nur folgende API-Funktion
Private Declare Function URLDownloadToFile Lib "urlmon" _
  Alias "URLDownloadToFileA" ( _
  ByVal pCaller As Long, _
  ByVal szURL As String, _
  ByVal szFileName As String, _
  ByVal dwReserved As Long, _
  ByVal lpfnCB As Long) As Long

Die Funktion erwartet folgende Parameter:

pCaller:	0
szURL:	URL-Link der Datei
szFileName:	vollständiger Dateiname der lokalen Datei
dwReserved:	0
lpfnCB:	0

Beispiel:

Dim lResult As Long
Dim sURL As String
Dim sLocalFile As String
 
' URL-Link der Datei, die heruntergeladen werden soll
sURL = "http://www.tools4vb.de/download/sevTrayIcon.zip"
 
' Dateiname auf dem lokalen System
sLocalFile = "C:\Eigene Dateien\sevTrayIcon.zip"
 
' Download ausführen
Screen.MousePointer = vbHourglass
lResult = URLDownloadToFile(0, sURL, sLocalFile, 0, 0)
Screen.MousePointer = vbNormal
 
' Rückgabewert auswerten
If lResult = 0 Then
  MsgBox "Download erfolgreich ausgeführt!"
Else
  MsgBox "Fehler beim Download: " & _
   "Entweder existiert die URL nicht, oder Sie haben " & _
   "einen ungültigen Dateinamen angegeben!", vbCritical
End If

Hinweis
Diese Variante des Datei-Downloads eignet sich nur für kleinere Dateien, da Ihr Programm während des Download-Vorgangs die Kontrolle an die DLL-Funktion abgibt. Erst nach dem Download arbeitet Ihr Programm weiter. Es empfiehlt sich daher auch vor dem Starten des Downloads einen Hinweis anzuzeigen - z.B. ein Status-Label mit "Bitte warten...".

...
' Status einblenden: Bitte warten...
Screen.MousePointer = vbHourglass
lblStatus.Caption = "Bitte warten..."
lblStatus.Visible = True
DoEvents
 
' Download ausführen
lResult = URLDownloadToFile(0, sURL, sLocalFile, 0, 0)
 
' Status wieder ausblenden
lblStatus.Visible = False
Screen.MousePointer = vbNormal
 
...