Parameter aus einem String zurückgeben Mit der GetToken-Funktion ist es möglich, schnell und einfach Parameter eines Strings zurückzugeben.
Autor:   Stefan Schindler	Bewertung:     [ Jetzt bewerten ]	Views:  15.811
ohne Homepage	System:  Win9x, WinNT, Win2k, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 25 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.7 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Ab VB6 gibt es ja bekanntlich die neuen Funktionen Split und Join. Jedoch scheint es manchmal umständlich, jedes Mal eine Variable zu deklarieren, die die Argumente hält.

Beispiel:
In einem String befindet sich eine vollständige Anschrift eines Kunden. Der String ist hierbei wie folgt aufgebaut:

Anrede|Name|Straße|Plz|Ort|Land

Sie möchten nun den Namen aus dem Gesamtstring ermitteln. Mittels Split würde das so aussehen:

Dim sData() As String
sData = Split(sString, "|")
MsgBox "Name: " & sData(1)

Mit nachfolgender Funktion ist es möglich, schnell und einfach ein Argument zurückzugeben, ohne den String erst aufteilen zu müssen. Außerdem ist diese Funktion auch für Versionen unter VB6 gültig.

Public Function GetToken(sText As String, _
  iPos As Integer, _
  Optional sDelimiter As String = " ") As String
 
  Dim iTotal As Integer
  Dim iCurPos As Integer
  Dim iLastPos As Integer
  Dim sAttach As String
 
  ' Erstes Trennungszeichen suchen
  iLastPos = Len(sDelimiter) * -1 + 1
  iCurPos = InStr(1, sText, sDelimiter)
 
  Do Until iCurPos = 0
    iTotal = iTotal + 1
 
    ' Trennungszeichen gefunden
    If iTotal >= iPos Then ' Gewünschte Position erreicht?
      Exit Do
    End If
 
    iLastPos = iCurPos
    iCurPos = InStr(iCurPos + 1, sText, sDelimiter)
  Loop
 
  ' Wenn kein Trennungszeichen gefunden wurde,
  ' kompletten Text zurückgeben
  If iCurPos = 0 And iPos = 1 Then
    sAttach = sText
 
  ' Falls gefunden, richtigen Parameter zurückgeben
  ElseIf iTotal = iPos Then
    sAttach = Mid$(sText, iLastPos + Len(sDelimiter), _
      iCurPos - iLastPos - Len(sDelimiter))
 
  ElseIf iTotal = iPos - 1 Then
    sAttach = Mid$(sText, iLastPos + Len(sDelimiter))
  End If
 
  GetToken = sAttach
End Function

Auf unser obigens Beispiel bezogen, würde das Ermitteln des Namens aus dem Gesamtstring nun so aussehen:

MsgBox GetToken(sString, 2, "|")