Bestimmte Zeile einer MultiLine-TextBox auslesen Die Funktion tbGetLine ermöglicht das gezielte Auslesen einer bestimmten Zeile einer MutliLine-TextBox.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  29.413
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 31 Bewertung insgesamt: gut Durchschnittliche Bewertung: 3.5 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Haben Sie sich auch schon einmal gefragt, wie sich der Inhalt einer bestimmte Zeile einer MutliLine-TextBox schnell ermitteln lässt? Hierzu haben wir Ihnen vor langer Zeit schon einmal einen Tipp vorgestellt:
 Bestimmte Zeile einer TextBox ermitteln

Bei obigem Tipp wurden jedoch nur Zeilen mit harten Umbruchzeichen berücksichtigt. Wird der Text innerhalb der TextBox jedoch autom. umgebrochen, müssen wir auf das Windows API zurückgreifen:

' zunächst die benötigten API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal wParam As Long, _
  ByVal lParam As Any) As Long
 
Private Const EM_GETLINE = &HC4
Private Const EM_GETLINECOUNT = &HBA

Als erstes ermitteln wir die gesamte Anzahl Zeilen der MutliLine-TextBox, um sicherzustellen, dass ein gültiger Zeilen-wert angegeben wurde:

nCount = SendMessage(Text1.hwnd, EM_GETLINECOUNT, 0, 0&)

Wurde ein gültiger Zeilenindex angegeben, d.h. liegt der übergebene Wert zwischen 1 und nCount, lesen wir die gewünschte Zeile aus. SendMessage liefert uns in diesem Fall die Länge der Zeile.

sLine = Space$(1024)
nLen = SendMessage(Text1.hwnd, EM_GETLINE, nLine - 1, sLine)

Das ganze verpacken wir nun in eine universelle Funktion. Als Parameter erwartet unsere Funktion das Handle der MultiLine-TextBox, sowie den Zeilenindex (1...nCount). Wurde ein gültiger Zeilenindex angegeben, gibt die Funktion den Inhalt der Zeile zurück, andernfalls vbNullString.

' Bestimmte Zeile einer MutliLine-TextBox auslesen
Public Function tbGetLine(ByVal hWnd As Long, _
  ByVal nLine As Long) As String
 
  Dim nLineCount As Long
  Dim nLen As Long
  Dim sLine As String
 
  ' zunächst die Anzahl der Zeilen ermitteln
  nLineCount = SendMessage(hwnd, EM_GETLINECOUNT, 0, 0&)
 
  If nLine > 0 And nLine <= nLineCount Then
    ' Jetzt Zeile auslesen
    sLine = Space$(1024)
    nLen = SendMessage(hwnd, EM_GETLINE, nLine - 1, sLine)
 
    tbGetLine = Left$(sLine, nLen)
  Else
    ' Ungültiger Zeilen-Index
    tbGetLine = vbNullString
  End If
End Function

Beispiel:

Dim sLine As String
 
' 3. Zeile ermitteln
sLine = tbGetLine(Text1.hWnd, 3)

Ist sLine = "" kann es sein, dass a) die Zeile keinen Text enthält (also leer ist) oder b) ein ungültiger Zeilenindex angegeben wurde. Sie können dies ermitteln, indem Sie den Funktionsrückgabewert wie folgt prüfen:

sLine = tbGetLine(Text1.hWnd, 3)
If StrPtr(sLine) = 0 Then
  ' Ungültiger Zeilenindex
Else
  MsgBox "Zeileninhalt: " & sLine
End If

Anmerkung / Erweiterung von Bernd Lucas
Bei einigen Win2000-Systemen taucht sporadisch der Fehler auf, das eine Leerzeile zurückgegeben wird.
Nach Abänderung der festdiminsionierung "sLine = Space$(1024)" in "MAX_CHAR_PER_LINE" trat dieser Fehler nicht mehr auf.

' Erweiterung der API-Deklarationen
Private Const MAX_CHAR_PER_LINE As Long = &H100&

' Änderung der Funktion "tbGetLine"
Public Function tbGetLine(ByVal hWnd As Long, _
  ByVal nLine As Long) As String
 
  Dim nLineCount As Long
  Dim nLen As Long
  Dim sLine As String
  Dim Lo As Long
  Dim Hi As Long
 
  ' zunächst die Anzahl der Zeilen ermitteln
  nLineCount = SendMessage(hWnd, EM_GETLINECOUNT, 0, 0&)
 
  If nLine > 0 And nLine <= nLineCount Then
    ' Jetzt Zeile auslesen
    Lo = MAX_CHAR_PER_LINE And &HFF
    Hi = Int(MAX_CHAR_PER_LINE / &H100)
    sLine = Chr$(Lo) & Chr$(Hi) & Space$(MAX_CHAR_PER_LINE - 2)
    nLen = SendMessage(hWnd, EM_GETLINE, nLine - 1, sLine)
 
    tbGetLine = Left$(sLine, nLen)
  Else
    ' Ungültiger Zeilen-Index
    tbGetLine = vbNullString
  End If
End Function