Wochendatum anhand Kalenderwoche ermitteln Dieser Tipp verrät, wie sich das Wochendatum (Montag - Sonntag) einer bestimmten Kalenderwoche ermitteln lässt.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  36.471
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 26 Bewertung insgesamt: sehr gut Durchschnittliche Bewertung: 4.8 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Unser heutiger Tipp zeigt einen Weg, wie sich das Wochendatum (Montag - Sonntag) einer bestimmten Kalenderwoche eines beliebigen Jahres ermitteln lässt.

Für den umgekehrten Weg, d.h. ist ein Datum bekannt und man möchte die Kalenderwoche wissen, bietet VB ja bereits eine fertige Lösung:

Dim nWeek As Integer
nWeek = Val(Format$(vDatum, "ww", vbMonday, vbFirstFourDays))

Wie sieht es aber aus, wenn nur die Kalenderwoche bekannt ist und man jetzt das Datum dieser Kalenderwoche benötigt?

Und genau das zeigt Ihnen nachfolgender Tipp.

Public Function GetDateFromWeek(ByVal nWeek As Integer, _
  Optional ByVal nDayOfWeek As VBA.VbDayOfWeek = vbMonday, _
  Optional ByVal nYear As Integer = -1) As Date
 
  Dim nCurWeek As Integer
  Dim vStart As Variant
  Dim vMonday As Variant
  Dim vSunday As Variant
  Dim nDay As Integer
 
  ' Kein Jahr angeben? Dann aktuelles Jahr verwenden!
  If nYear = -1 Then nYear = Year(Now)
 
  ' aktuelle Woche im Jahr nYear ermitteln
  vStart = DateSerial(nYear, Month(Now), Day(Now))
  nCurWeek = Val(Format$(vStart, "ww", vbMonday))
 
  ' Datum der gewünschten Woche ermitteln
  vStart = DateAdd("ww", nWeek - nCurWeek, vStart)
 
  ' Wochenanfang ermitteln
  nDay = Weekday(vStart, vbMonday)
 
  ' Datum des gewünschten Wochentags ermitteln
  If nDayOfWeek = vbSunday Then
    GetDateFromWeek = DateAdd("d", -nDay + 7, vStart)
  Else
    GetDateFromWeek = DateAdd("d", -nDay + nDayOfWeek - 1, vStart)
  End If
End Function

Nehmen wir an, Sie benötigen das Datum für den Montag, sowie den darauffolgenden Sonntag der 12. Kalenderwoche im Jahr 2003:

Dim vMonday As Date
Dim vSunday As Date
 
vMonday = GetDateFromWeek(12, vbMonday, 2003)
vSunday = GetDateFromWeek(12, vbSunday, 2003)

Hinweis:
Die obige Funktion sieht Montag als den 1. Tag der Woche an und demzufolge Sonntag als den letzten Tag der Woche!