vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Mails senden, abrufen und decodieren - ganz easy ;-)  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2024
 
zurück
Rubrik: Grafik und Font · Font & Text   |   VB-Versionen: VB4, VB5, VB627.10.03
Text mit Farbmaske erstellen

Dieser Tipp zeigt, wie sich ein Text unter Berücksichtigung einer Farbmaske in einer PictureBox ausgeben lässt.

Autor:   LonelySuicide666Bewertung:     [ Jetzt bewerten ]Views:  12.343 
www.vbapihelpline.deSystem:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11 Beispielprojekt auf CD 

Heute zeigen wir Ihnen, wie sich ein grafischer Text unter Berücksichtigung einer Farbmaske in einer PictureBox ausgeben lässt.

Starten Sie ein neues Projekt und platzieren auf die Form:

  • eine TextBox namens Text1
  • 3 PictureBox-Controls namens Picture1, Picture2 und Picture3

Im ersten PictureBox-Control soll der Text aus der TextBox ganz normal in schwarzer Schrift angezeigt werden. Die zweite PictureBox enthält ein Farbverlauf oder ein beliebiges Bild. Im dritten PictureBox-Control soll letztendlich die Kombination aus der 1. PictureBox und der 2. PictureBox angezeigt werden.

Für unser Beispiel verwenden wir als Farbmaske einen Farbverlauf:

Option Explicit
 
' benötigte API-Deklarationen
Private Declare Function BitBlt Lib "gdi32" ( _
  ByVal hDestDC As Long, _
  ByVal x As Long, _
  ByVal y As Long, _
  ByVal nWidth As Long, _
  ByVal nHeight As Long, _
  ByVal hSrcDC As Long, _
  ByVal xSrc As Long, _
  ByVal ySrc As Long, _
  ByVal dwRop As Long) As Long
 
Private Declare Function SetBkColor Lib "gdi32" ( _
  ByVal hdc As Long, _
  ByVal crColor As Long) As Long
 
Private Const SRCINVERT = &H660046
Private Const SRCAND = &H8800C6
Private Sub Form_Load()
  ' AutoRedraw muss auf TRUE festgelegt sein!
  Picture1.AutoRedraw = True
  Picture2.AutoRedraw = True
  Picture3.AutoRedraw = True
 
  ' Schriftgröße festlegen
  Picture1.Font.Name = "Times New Roman"
  Picture1.Font.Size = 36
  Picture1.Font.Bold = True
 
  Set Picture3.Font = Picture1.Font
 
  ' Farbverlauf erstellen
  MakeGradient Picture2, vbBlue, vbWhite, 1
 
  ' Text anzeigen
  Text1_Change
End Sub
' Text mit Farbmaske ausgeben
Private Sub Text1_Change()
  Dim DestCX As Long
  Dim DestCY As Long
  Dim TmpBackColor As Long
 
  ' Quelltext aus TextBox in der 1. PictureBox
  ' anzeigen (das Bildfeld muß
  ' schwarz/weiß sein)
  With Picture1
    .Cls
    .BackColor = vbWhite
    .ForeColor = vbBlack
    Picture1.Print Text1.Text
  End With
 
 
  With Picture3
    ' Größe/Dimension des Ausgabebildes
    DestCX = .Width / Screen.TwipsPerPixelX
    DestCY = .Height / Screen.TwipsPerPixelY
 
    ' Ausgabebereich löschen
    .Cls
 
    ' Hintgrundfarbe der Quelle übernehmen
    ' (immer weiß)
    TmpBackColor = .BackColor
    SetBkColor .hdc, Picture1.BackColor
 
    ' Quelle mit der Farbmaske in einem
    ' Bildfeld überzeichnen
    BitBlt .hdc, 0, 0, DestCX, DestCY, Picture2.hdc, _
      0, 0, SRCINVERT
    BitBlt .hdc, 0, 0, DestCX, DestCY, Picture1.hdc, _
      0, 0, SRCAND
    BitBlt .hdc, 0, 0, DestCX, DestCY, Picture2.hdc, _
      0, 0, SRCINVERT
 
    ' Hintergundfarbe wiederherstellen
    SetBkColor .hdc, TmpBackColor
 
    ' Bild anzeigen
    .Refresh
  End With
End Sub

Anmerkung:

Die MakeGradient-Prozedur stammt aus folgendem Tipp:
 Farbverlauf in Fenstern und Objekten
 

Dieser Tipp wurde bereits 12.343 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2024 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel