SplitString Parser mit Start- und End Delimiter Gibt alle zwischen Start- und End-Delimiter befindlichen Strings in ein Array zurück.
Autor:   Thomas Demmler	Bewertung:     [ Jetzt bewerten ]	Views:  13.834
ohne Homepage	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	kein Beispielprojekt

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 14 Bewertung insgesamt: nützlich Durchschnittliche Bewertung: 2.8 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Funktionen zur Rückgabe einzelner String-Abschnitte, die durch ein Trennzeichen getrennt sind, gibt es ja verschiedene. Will man jedoch alles zwischen zwei verschiedenen Trennzeichen ermitteln, dann wird es karg. Nachfolgend eine Funktion, die das erledigt:

Public Function garrFormelParser(sFormel As String, _
  Optional sDelimStart As String = "[", _
  Optional sDelimEnd As String = "]") As Variant
 
  Dim sLink() As String
  Dim sFormelCut As String
  Dim lLinkStart As Long
  Dim lLinkEnde As Long
  Dim i As Long
 
  i = 1
  sFormelCut = sFormel
 
  ' erstes Auftreten des sDelimStart ermitteln
  lLinkStart = InStr(1, sFormelCut, sDelimStart)
  While lLinkStart > 0
    ' so lange weiter in sFormel suchen, bis sDelimStart nicht mehr auftritt
    ' erstes Auftreten des sDelimEnd ermitteln
    lLinkEnde = InStr(1, sFormelCut, sDelimEnd)
 
    ' Array-Dimensionierung vergrößern
    ReDim Preserve sLink(1 To i) As String
 
    ' String zwischen sDelimStart unf sDelimEnd in Array übergeben
    sLink(i) = Mid$(sFormelCut, lLinkStart + 1, (lLinkEnde - lLinkStart - 1))
    i =i  + 1
 
    ' ausgewerteten Teil der Ursprünglichen Formel abschneiden und nur mit
    ' dem Rest weiterarbeiten
    sFormelCut = Mid$(sFormelCut, lLinkEnde + 1)
 
    ' erstes Auftreten des sDelimStart ermitteln
    lLinkStart = InStr(1, sFormelCut, sDelimStart)
  Wend
  garrFormelParser = sLink
End Function

Eine Anwendung wäre das Parsen einer Formel zur weiteren Berechnung, die als Variablen Links zu Tabellenfeldern enthält - z.B. folgende Formel:

[DB:=UserDatenbank;Table:=Parameter;Key:=ParameterID = 201;Value:=Anzahl]*
[DB:=UserDatenbank;Table:=Parameter;Key:=ParameterID = 225;Value:=Breite]

Die Formel enthält also 2 Variablen, die jeweils auf einen anderen Datensatz in der Tabelle "Parameter" in der Datenbank "UserDatenbank" verweisen. Diese beiden Variablen müssen für die entgültige Berechnung der Formel geparst werden. Um das tun zu können, müssen sie jedoch erst einzeln aus dem String der Gesamt-Formel ermittelt werden - also:

Private Sub Command1_Click()
  Dim vArray As Variant
  Dim sFormel As String
 
  sFormel = "[DB:=UserDatenbank;Table:=Parameter;Key:=ParameterID = 201;Value:=Anzahl]*" & _
    "[DB:=UserDatenbank;Table:=Parameter;Key:=ParameterID = 225;Value:=Breite]"
 
  vArray = garrFormelParser(sFormel)
End Sub

Als Ergebnis erhält man ein Array mit allen in der Formel auftretenden Variablen, die in "[" und "]" eingefasst sind...

Viel Spaß damit.