vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Top-Preis! AP-Access-Tools-CD Volume 1  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2021
 
zurück
Rubrik: Controls · ListBox   |   VB-Versionen: VB5, VB631.05.05
Mehrere ListBoxen parallel scrollen

Dieser Tipp zeigt, wie sich mehrere ListBox-Controls parallel zueinandern scrollen lassen.

Autor:   Rolf WahlbrinckBewertung:     [ Jetzt bewerten ]Views:  13.073 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10 Beispielprojekt auf CD 

Befinden sich zwei oder noch mehr Listboxen mit einer gleichen Anzahl Elemente auf einem Formular, und soll beim Auswählen eines Elementes der Liste 1 parallel auch das entsprechende Element der Liste 2 selektiert werden, so hilft Ihnen dieser Tipp weiter.

Erstellen Sie ein neues Projekt und platzieren auf die Form drei ListBox-Controls als Control-Array (List1(0), List(1) und List1(2)). Fügen Sie nachfolgenden Code zunächst in ein Modul ein:

Option Explicit
 
' Benötigte API-Deklarationen
Private Declare Function SendMessage Lib "user32" _
  Alias "SendMessageA" ( _
  ByVal hwnd As Long, _
  ByVal wMsg As Long, _
  ByVal Param As Long, _
  lParam As Any) As Long
 
Private Const LB_SETCURSEL = &H186
Private Const LB_SETTOPINDEX = &H197
Public Sub ListenBeiClickEreignisAngleichen(ListB As Object, Index As Integer)
  Dim LIndex As Long
  Dim LB     As ListBox
 
  ' ListIndex suchen
  For Each LB In ListB
    If LB.Index = Index Then
      LIndex = LB.ListIndex
      Exit For
    End If
  Next LB
 
  ' ListIndex setzen
  For Each LB In ListB
    If LB.Index <> Index Then
      SendMessage LB.hwnd, LB_SETCURSEL, LIndex, 0&
     End If
  Next LB
End Sub
Public Sub ListenBeiScrollEreignisAngleichen(ListB As Object, Index As Integer)
  Dim LIndex As Long
  Dim LB     As ListBox
 
  ' TopIndex suchen
  For Each LB In ListB
    If LB.Index = Index Then
      LIndex = LB.TopIndex
      Exit For
    End If
  Next LB
 
  ' TopIndex setzen
  For Each LB In ListB
    If LB.Index <> Index Then
      SendMessage LB.hwnd, LB_SETTOPINDEX, LIndex, 0&
    End If
  Next LB
End Sub

Fügen Sie jetzt noch nachfolgenden Code in den Codeteil der Form1 ein:

Private Sub Form_Load()
  Dim i As Long
 
  ' ListBoxen füllen
  For i = 1 To 100
    List1(0).AddItem "Eintrag " & CStr(i)
    List1(1).AddItem "Eintrag " & CStr(i)
    List1(2).AddItem "Eintrag " & CStr(i)
  Next i
End Sub

Beim Auswählen eines Eintrags oder beim Scrollen über die Scrollbar muss die Ansicht der beiden anderen ListBoxen ebenfalls aktualisiert werden:

Private Sub List1_Click(Index As Integer)
  ListenBeiClickEreignisAngleichen List1, Index
End Sub
Private Sub List1_Scroll(Index As Integer)
  ListenBeiScrollEreignisAngleichen List1, Index
End Sub

Dieser Tipp wurde bereits 13.073 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6
(einschl. Beispielprojekt!)

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2021 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel