IsInArray - Element in Array vorhanden? Mit dieser kleinen Funktion lässt sich prüfen, ob ein bestimmtes Element in einem Datenfeld (Array) existiert.
Autor:   Dieter Otter	Bewertung:     [ Jetzt bewerten ]	Views:  51.642
https://www.tools4vb.com	System:  Win9x, WinNT, Win2k, WinXP, Win7, Win8, Win10, Win11	Beispielprojekt auf CD

Geben Sie hier Ihre persönliche Bewertung ab! Anzahl Bewertungen bisher: 6 Bewertung insgesamt: gut Durchschnittliche Bewertung: 4.2 von 5 Sternen

sehr gut     gut     nützlich     mittelmäßig     mangelhaft

Innerhalb der eigenen Anwendung verwendet man oftmals Datenfelder (Arrays), in denen Text-Informationen abgelegt werden.

Mit nachfolgender Funktion lässt sich prüfen, ob im String-Array ein bestimmter Eintrag vorhanden ist. Die Funktion gibt im Erfolgsfall die Position des Elementes innerhalb des Arrays zurück. Ist der Eintrag hingegen nicht im Array vorhanden, wird der Wert -1 zurückgegeben. Weiterhin lässt sich über die beiden optionalen Parameter noch der Start- und Endbereich des Arrays angeben, das für die Suche herangezogen werden soll.

Public Function IsInArray(ByRef sArray() As String, _
  ByVal sItem As String, _
  Optional ByVal nStart As Variant, _
  Optional ByVal nEnd As Variant) As Long
 
  ' Prüfen, ob das Element "sItem" im Array "sArray" enthalten ist
  ' Rückgabewert: Index des Elements bzw. -1, wenn nicht vorhanden
  Dim i As Long
  Dim nIndex As Long
  Dim nLen As Long
 
  On Error GoTo ErrHandler
  nIndex = -1
 
  If IsMissing(nStart) Then nStart = LBound(sArray)
  If IsMissing(nEnd) Then nEnd = UBound(sArray)
 
  nLen = Len(sItem)
  For i = nStart To nEnd
    If Len(sArray(i)) = nLen Then
      If sArray(i) = sItem Then
        nIndex = i: Exit For
      End If
    End If
  Next i
  On Error GoTo 0
 
ErrHandler:
  IsInArray = nIndex
End Function

Anwendungsbeispiele

Elemente sollen nur dann ins Array aufgenommen werden, wenn diese noch nicht vorhanden sind:

Dim sData() As String
Dim sElement As String
...
 
ReDim sData(0)
...
 
If IsInArray(sData(), sElement) < 0 Then
  ReDim Preserve sData(UBound(sData) + 1)
  sData(UBound(sData)) = sElement
End If

Suche nach einem bestimmten Element innerhalb des Arrays und Ausgabe der Position (Index):

Dim nIndex As Long
nIndex = IsInArray(sData(), sElement)
If nIndex >= 0 Then
  MsgBox "Element an Position " & CStr(nIndex) & " gefunden."
Else
  MsgBox "Element nicht im Array vorhanden."
End If