vb@rchiv
VB Classic
VB.NET
ADO.NET
VBA
C#
Top-Preis! AP-Access-Tools-CD Volume 1  
 vb@rchiv Quick-Search: Suche startenErweiterte Suche starten   RSS-Feeds  | Newsletter  | Impressum  | Datenschutz  | vb@rchiv CD Vol.6  | Shop Copyright ©2000-2018
 
zurück
Rubrik: Variablen/Strings · Arrays   |   VB-Versionen: VB619.01.09
String-Array verbinden II

Diese Funktion erweitert ein Array um ein zweites Array. Die Daten werden nicht kopiert, lediglich Zeiger werden umgespeichert.

Autor:   Rolf WahlbrinckBewertung:     [ Jetzt bewerten ]Views:  8.813 
ohne HomepageSystem:  Win9x, WinNT, Win2k, WinXP, Vista, Win7, Win8, Win10kein Beispielprojekt 

Die Funktion AddStringArray nimmt den Hinweis aus dem Tipp  String-Arrays verbinden auf und erweitert ein Array um ein zweites Array. Die Daten werden hierbei nicht kopiert, lediglich Zeiger werden umgespeichert. Das zweite Array ist nach der Operation leer!

' benötigte API-Deklaration
Private Declare Sub CopyMemory Lib "kernel32" _
  Alias "RtlMoveMemory" ( _ 
  Dest As Any, _
  Source As Any, _
  ByVal Bytes As Long)
Sub AddStringArray(ByRef StammArray() As String, ByRef AddArray() As String)
  ' Hier werden nur die Pointer "geswapt"!
  ' Achtung: AddArray() ist nach dem Aufruf immer leer, 
  ' muss ggf. vorher gesichert werden.
  ' Achtung: Lbound(StammArray()) = 0 wird erwartet.
  ' Achtung: Lbound(AddArray()) = 0 wird erwartet.
  ' Aufruf:
  ' AddStringArray StammArray(), AddArray()
 
  Dim BackUpArray() As Long
  Dim CopyByteAnzahl As Long
  Dim UBStammArray As Long
  Dim UBAddArray As Long
  Dim StammArrayok As Boolean
  Dim AddArrayok As Boolean
 
  If (Not (Not StammArray())) <> 0 Then StammArrayok = True
  If (Not (Not AddArray())) <> 0 Then AddArrayok = True
 
  ' Normalfall, beide Felder nicht leer
  If StammArrayok = True And AddArrayok = True Then
 
    ' Eckwerte holen, vor Vergrößerung!
    UBStammArray = UBound(StammArray())
    UBAddArray = UBound(AddArray())
 
    ' StammArary vergrößern
    ReDim Preserve StammArray(UBStammArray + UBAddArray + 1)
 
    ' BakupFeld herrichten
    ReDim BackUpArray(UBAddArray + 1)
 
    ' Anzahl definieren
    CopyByteAnzahl = (UBAddArray + 1) * 4
 
    ' copy Memory (1),
    ' Zeiger der oberen, leeren StammArray-Plätze -> BackUpArray
    CopyMemory ByVal VarPtr(BackUpArray(0)), _
      ByVal VarPtr(StammArray(UBStammArray + 1)), ByVal CopyByteAnzahl
 
    ' copy Memory (2),
    ' Zeiger AddArray() -> obere, leere StammArray-Plätze
    CopyMemory ByVal VarPtr(StammArray(UBStammArray + 1)), _
      ByVal VarPtr(AddArray(0)), ByVal CopyByteAnzahl
 
    ' copy Memory (3),
    ' BackUpArray -> Zeiger AddArray()
    CopyMemory ByVal VarPtr(AddArray(0)), _
      ByVal VarPtr(BackUpArray(0)), ByVal CopyByteAnzahl
 
  ' Sonderfälle
  ElseIf StammArrayok = False And AddArrayok = False Then
    ' beide leer
    StammArray() = Split("", vbCrLf$, -1, vbBinaryCompare)
 
  ElseIf StammArrayok = False Then
    ' Feld 1 leer / Feld 2 nicht leer
    StammArray() = AddArray()
  End If
 
  ' AddArray() löschen, wurde sowieso geändert, ggf. daher vorher sichern
  ' alternativ wäre auch Erase AddArray() möglich 
  AddArray() = Split("", vbCrLf$, -1, vbBinaryCompare)
End Sub

Aufrufbeispiel:

Dim Array1() As String
Dim Array2() As String
 
Array1() = Split("Meyer1 Müller1 Schulz1")
Array2() = Split("Meyer2 Müller2 Schulz2")
' Array1 mit allen Werten aus Array2 erweitern
' Array2 ist anschließend leer!
AddStringArray Array1(), Array2()
 
Dim i As Long
For i = 0 To UBound(Array1)
  Debug.Print i, Array1(i)
Next i

Dieser Tipp wurde bereits 8.813 mal aufgerufen.

Voriger Tipp   |   Zufälliger Tipp   |   Nächster Tipp

Über diesen Tipp im Forum diskutieren
Haben Sie Fragen oder Anregungen zu diesem Tipp, können Sie gerne mit anderen darüber in unserem Forum diskutieren.

Neue Diskussion eröffnen

nach obenzurück


Anzeige

Kauftipp Unser Dauerbrenner!Diesen und auch alle anderen Tipps & Tricks finden Sie auch auf unserer aktuellen vb@rchiv  Vol.6

Ein absolutes Muss - Geballtes Wissen aus mehr als 8 Jahren vb@rchiv!
- nahezu alle Tipps & Tricks und Workshops mit Beispielprojekten
- Symbol-Galerie mit mehr als 3.200 Icons im modernen Look
Weitere Infos - 4 Entwickler-Vollversionen (u.a. sevFTP für .NET), Online-Update-Funktion u.v.m.
 
   

Druckansicht Druckansicht Copyright ©2000-2018 vb@rchiv Dieter Otter
Alle Rechte vorbehalten.
Microsoft, Windows und Visual Basic sind entweder eingetragene Marken oder Marken der Microsoft Corporation in den USA und/oder anderen Ländern. Weitere auf dieser Homepage aufgeführten Produkt- und Firmennamen können geschützte Marken ihrer jeweiligen Inhaber sein.

Diese Seiten wurden optimiert für eine Bildschirmauflösung von mind. 1280x1024 Pixel